File Coverage

blib/lib/SQL/Maker/SelectSet.pm

Criterion	Covered	Total	%
statement	71	74	95.9
branch	9	16	56.2
condition	1	3	33.3
subroutine	17	17	100.0
pod	4	6	66.6
total	102	116	87.9

package SQL::Maker::SelectSet;
use strict;
use warnings;
use parent qw(Exporter);
use Scalar::Util ();
use Carp ();
use SQL::Maker::Util;
use Class::Accessor::Lite (
    ro => [qw/new_line operator/],
);

our @EXPORT_OK = qw(union union_all intersect intersect_all except except_all);

# Functions
BEGIN {
    for (qw/union union_all intersect intersect_all except except_all/) {
        my $method = $_;
        (my $operator = uc $_) =~ s/_/ /;

        no strict 'refs';
        *{__PACKAGE__ . '::' . $method} = sub {
            my $stmt = SQL::Maker::SelectSet->new(
                operator => $operator,
                new_line => $_[0]->new_line,
            );
            $stmt->add_statement($_) for @_;
            return $stmt;
        };
    }
}

#
# Methods
#

sub new {
    my $class = shift;
    my %args = @_==1 ? %{$_[0]} : @_;
    Carp::croak("Missing mandatory parameter 'operator' for SQL::Maker::SelectSet->new") unless exists $args{operator};

    my $set = bless {
        new_line   => qq{\n},
        %args,
    }, $class;

    return $set;
}

sub add_statement {
    my ($self, $statement) = @_;

    unless ( Scalar::Util::blessed($statement) and $statement->can('as_sql') ) {
        Carp::croak( "'$statement' doesn't have 'as_sql' method.");
    }
    push @{$self->{statements}}, $statement;
    return $self; # method chain
}

sub as_sql_order_by {
    my ($self) = @_;

    my @attrs = @{$self->{order_by}};
    return '' unless @attrs;

    return 'ORDER BY '
           . join(', ', map {
                my ($col, $type) = @$_;
                if (ref $col) {
                    $$col
                } else {
                    $type ? $self->_quote($col) . " $type" : $self->_quote($col)
                }
           } @attrs);
}

sub _quote {
    my ($self, $label) = @_;

    return $$label if ref $label eq 'SCALAR';
    SQL::Maker::Util::quote_identifier($label, $self->{quote_char}, $self->{name_sep})
}

sub as_sql {
    my ($self) = @_;

    my $new_line = $self->new_line;
    my $operator = $self->operator;

    my $sql = join(
        $new_line . $operator . $new_line,
        map { $_->as_sql } @{ $self->{statements} }
    );
    $sql .= ' ' . $self->as_sql_order_by() if $self->{order_by};
    return $sql;
}

sub bind {
    my ($self) = @_;
    my @binds;
    for my $select ( @{ $self->{statements} } ) {
        push @binds, $select->bind;
    }
    return @binds;
}

sub add_order_by {
    my ($self, $col, $type) = @_;
    push @{$self->{order_by}}, [$col, $type];
    return $self;
}

1;
__END__