File Coverage

blib/lib/SOAP/Transport/POP3.pm

Criterion	Covered	Total	%
statement	18	48	37.5
branch	0	18	0.0
condition	0	9	0.0
subroutine	6	12	50.0
pod			n/a
total	24	87	27.5

# ======================================================================
#
# Copyright (C) 2000-2001 Paul Kulchenko ([e-mail])
# SOAP::Lite is free software; you can redistribute it
# and/or modify it under the same terms as Perl itself.
#
# ======================================================================

package SOAP::Transport::POP3;

use strict;

our $VERSION = 1.11;

use Net::POP3;
use URI;

# ======================================================================

package SOAP::Transport::POP3::Server;

use Carp ();
use vars qw(@ISA $AUTOLOAD);
@ISA = qw(SOAP::Server);

sub DESTROY { my $self = shift; $self->quit if $self->{_pop3server} }

sub new {
    my $class = shift;
    return $class if ref $class;

    my $address = shift;
    Carp::carp "URLs without 'pop://' scheme are deprecated. Still continue"
      if $address =~ s!^(pop://)?!pop://!i && !$1;
    my $server = URI->new($address);
    my $self = $class->SUPER::new(@_);
    $self->{_pop3server} = Net::POP3->new($server->host_port)
        or Carp::croak "Can't connect to '@{[$server->host_port]}': $!";
    my $method = ! $server->auth || $server->auth eq '*'
        ? 'login'
        : $server->auth eq '+APOP'
            ? 'apop'
            : Carp::croak "Unsupported authentication scheme '@{[$server->auth]}'";
    $self->{_pop3server}->$method( split m{:}, $server->user() )
        or Carp::croak "Can't authenticate to '@{[$server->host_port]}' with '$method' method"
            if defined $server->user;
    return $self;
}

sub AUTOLOAD {
  my $method = substr($AUTOLOAD, rindex($AUTOLOAD, '::') + 2);
  return if $method eq 'DESTROY';

  no strict 'refs';
  *$AUTOLOAD = sub { shift->{_pop3server}->$method(@_) };
  goto &$AUTOLOAD;
}

sub handle {
  my $self = shift->new;
  my $messages = $self->list or return;
  # fixes [ 1416700 ] POP3 Processes Messages Out of Order
  foreach my $msgid (sort { $a <=> $b } (keys(%{$messages}) ) ) {
  # foreach my $msgid (keys %$messages) {
    $self->SUPER::handle(join '', @{$self->get($msgid)});
  } continue {
    $self->delete($msgid);
  }
  return scalar keys %$messages;
}

sub make_fault { return }

# ======================================================================

1;

__END__