File Coverage

blib/lib/Rex/JobControl/Mojolicious/Plugin/Audit.pm

Criterion	Covered	Total	%
statement	23	32	71.8
branch	0	2	0.0
condition	0	3	0.0
subroutine	7	8	87.5
pod	1	1	100.0
total	31	46	67.3

#
# (c) Jan Gehring
#
# vim: set ts=3 sw=3 tw=0:
# vim: set expandtab:

package Rex::JobControl::Mojolicious::Plugin::Audit;
$Rex::JobControl::Mojolicious::Plugin::Audit::VERSION = '0.18.0';
use strict;
use warnings;

use Mojolicious::Plugin;

use base 'Mojolicious::Plugin';
use Rex::JobControl::Helper::AuditLog;
use Data::Dumper;

sub register {
  my ( $plugin, $app ) = @_;

  my $log = Rex::JobControl::Helper::AuditLog->new(
    path  => $app->config->{log}->{audit_log},
    level => 'info'
  );

  my %audit_calls = %{ $app->config->{audit} };

  $app->hook(
    around_action => sub {
      my ( $next, $c, $action, $last ) = @_;

      my $ctrl_name   = $c->stash('controller');
      my $action_name = $c->stash('action');

      if ( exists $audit_calls{$ctrl_name}
        && exists $audit_calls{$ctrl_name}->{$action_name} )
      {
        my %params;
        @params{ @{ $audit_calls{$ctrl_name}->{$action_name}->{params} } } =
          $c->param( $audit_calls{$ctrl_name}->{$action_name}->{params} );

        $log->audit(
          {
            controller => $ctrl_name,
            action     => $action_name,
            data       => \%params,
          }
        );
      }

      return $next->();
    },
  );

}

1;