File Coverage

blib/lib/Regex/Object.pm

Criterion	Covered	Total	%
statement	50	51	98.0
branch	2	2	100.0
condition			n/a
subroutine	14	14	100.0
pod	3	3	100.0
total	69	70	98.5

package Regex::Object;

use 5.20.0;

use utf8;
use English;
use feature qw(signatures);

use Regex::Object::Match;
use Regex::Object::Matches;
use Moo;

no warnings qw(experimental::signatures);
use namespace::clean;

our $VERSION = '1.24';

tie my %nc,  "Tie::Hash::NamedCapture";
tie my %nca, "Tie::Hash::NamedCapture", all => 1;

has regex => (
    is => 'ro',
);

sub match($self, $string) {
    $string =~ $self->regex;
    return $self->collect;
}

sub match_all($self, $string) {
    my $regex = $self->regex;
    my @matches;

    while($string =~ /$regex/g) {
        push @matches, $self->collect;
    }

    return Regex::Object::Matches->new(
        collection => \@matches,
    );
}

sub collect {
    return Regex::Object::Match->new(
        prematch           => $PREMATCH,
        match              => $MATCH,
        postmatch          => $POSTMATCH,
        last_paren_match   => $LAST_PAREN_MATCH,
        captures           => _collect_captures(),
        named_captures     => { %nc },
        named_captures_all => { %nca },
    );
}

sub _collect_captures {
    my @captures;

    # Trick to get @captures the most appropriate to language version way.
    eval {
        @captures = @{^CAPTURE}; # This was added in 5.25.7.
    }
    or do {
        no strict 'refs';
        @captures = map { "$$_" } 1 .. $#-;
    };

    return \@captures;
}

1;

__END__