File Coverage

blib/lib/RPi/UnicornHatHD.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package RPi::UnicornHatHD;
#
use Moo;
use strictures 2;
use namespace::clean;
#
our $VERSION = "0.05";
#
use WiringPi::API;
#
my $spi_channel      = 0;
my $spi_max_speed_hz = 9000000;
my $sof              = 0x72;

# _DELAY = 1.0/120 # Leave this to the user
#
sub BUILD {
    my ($self, $args) = @_;
    if ((WiringPi::API::spi_setup($spi_channel, $spi_max_speed_hz) < 0)) {
        die "failed to open the SPI bus...\n";
    }
}
has brightness => (is => 'rw', default => sub {.5});
has rotation   => (is => 'rw', default => sub {0});
has matrix => (is => 'lazy', clearer => 'clear');

sub _build_matrix {
    [map {
         [map { [0, 0, 0] } 1 .. 16]
     } 1 .. 16
    ];
}

sub show {
    my @buffer     = $_[0]->_rotate;
    my $brightness = $_[0]->brightness;
    WiringPi::API::spiDataRW(0,
                             [$sof, map { $_ * $brightness } @buffer],
                             1 + scalar @buffer);
}

sub off {
    my $s = shift;
    $s->clear();
    $s->show();
}

sub set_all {
    my $s = shift;
    my ($r, $g, $b)
        = $#_ == 2 ?
        @_
        : (map { hex $_ } $_[0] =~ m[#(\w{2})(\w{2})(\w{2})]);
    for my $x (0 .. 15) {
        for my $y (0 .. 15) {
            $s->matrix->[$x][$y] = [$r, $g, $b];
        }
    }
}

sub set_pixel {
    my $s = shift;
    my ($x, $y, $r, $g, $b)
        = $#_ == 4 ?
        @_
        : (@_[0 .. 1], map { hex $_ } $_[2] =~ m[#(\w{2})(\w{2})(\w{2})]);
    $s->matrix->[$x][$y] = [$r, $g, $b];
}

sub get_pixel {
    my $s = shift;
    my ($x, $y) = @_;
    $s->matrix->[$x][$y];
}

sub _rotate {
    my $s  = shift;
    my $in = $s->matrix;
    for my $rot (0 .. (($s->rotation / 90) % 4 - 1)) {
        my @out  = ();
        my $rows = scalar @$in;
        for my $row (0 .. $rows - 1) {
            $out[$row] = [map { $_->[$row] } reverse @$in];
        }

        #wantarray ? @out : \@out;
        $in = \@out;
    }
    __flatten($in);
}

sub __flatten {
    map { ref $_ ? __flatten(@{$_}) : $_ } @_;
}
1;
__END__