File Coverage

blib/lib/Proc/Lite.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	8	8	100.0
condition			n/a
subroutine	11	11	100.0
pod	7	7	100.0
total	59	59	100.0

package Proc::Lite;

use strict;
use warnings;

use Carp;
use Proc::Hevy;

our $VERSION = '0.10';


sub new {
  my ( $class, @args ) = @_;

  confess 'Odd number of parameters'
    unless @args % 2 == 0;
  my %args = @args;

  confess 'command: Required parameter'
    unless defined $args{command};

  bless {
    command  => $args{command},
    stdin    => $args{stdin},
    stdout   => [ ],
    stderr   => [ ],
    status   => undef,
    parent   => $args{parent},
    child    => $args{child},
    priority => $args{priority},
  }, $class
}

sub exec {
  my ( $class, @command ) = @_;
  $class->new( command => \@command )->run;
}

sub run {
  my ( $self ) = @_;

  my $status = Proc::Hevy->exec(
    command  => $self->{command},
    stdin    => $self->{stdin},
    stdout   => $self->{stdout},
    stderr   => $self->{stderr},
    parent   => $self->{parent},
    child    => $self->{child},
    priority => $self->{priority},
  );

  $self->{status} = $status >> 8;

  $self
}

sub status  { my ( $self ) = @_; $self->{status} }

sub stdout  { my ( $self ) = @_; wantarray ? @{ $self->{stdout} } : $self->{stdout} }

sub stderr  { my ( $self ) = @_; wantarray ? @{ $self->{stderr} } : $self->{stderr} }

sub success { my ( $self ) = @_; $self->status == 0 }


1
__END__