File Coverage

blib/lib/Podman/Client.pm

Criterion	Covered	Total	%
statement	58	59	98.3
branch	16	18	88.8
condition			n/a
subroutine	16	16	100.0
pod			n/a
total	90	93	96.7

package Podman::Client;

use Mojo::Base -base;

our $VERSION     = '20220211.0';
our $API_VERSION = '3.0.0';

use English qw( -no_match_vars );
use Mojo::Asset::File;
use Mojo::Asset::Memory;
use Mojo::JSON qw(encode_json);
use Mojo::URL;
use Mojo::UserAgent;
use Mojo::Util qw(url_escape);

use Podman::Exception;

has 'connection_url' => sub {
  return $ENV{PODMAN_CONNECTION_URL}
    || ($UID != 0 ? "http+unix:///run/user/$UID/podman/podman.sock" : 'http+unix:///run/podman/podman.sock');
};

for my $name (qw(delete get post)) {
  Mojo::Util::monkey_patch(__PACKAGE__, $name, sub { return shift->_request(uc $name, @_); });
}

sub _base_url {
  my $self = shift;

  my $base_url = Mojo::URL->new($self->_connection_url->scheme eq 'http+unix' ? 'http://d/' : $self->connection_url);

  my $tx;
  my $url = $base_url->path('_ping');
  for (0 .. 3) {
    $tx = $self->_ua->get($url);
    last if $tx->res->is_success;
    sleep 1;
  }
  Podman::Exception->throw(900) unless $tx->res->is_success;

  $tx = $self->_ua->get($base_url->path('version'));
  my $version = $tx->res->json->{Components}->[0]->{Details}->{APIVersion};

  say {*STDERR} "Potential insufficient supported Podman service API version." if $version ne $API_VERSION;

  return $base_url->path('v' . $version . '/libpod/');
}

sub _connection_url { return Mojo::URL->new(shift->connection_url); }

sub _request {
  my ($self, $method, $path, %opts) = @_;

  my $url = $self->_base_url->path($path);
  $url->query($opts{parameters}) if $opts{parameters};

  my $tx = $self->_ua->build_tx($method => $url, $opts{headers});
  if ($opts{data}) {
    my $asset
      = ref $opts{data} eq 'Mojo::File'
      ? Mojo::Asset::File->new(path => $opts{data})
      : Mojo::Asset::Memory->new->add_chunk(encode_json($opts{data}));
    $tx->req->content->asset($asset);
  }
  $tx = $self->_ua->start($tx);

  Podman::Exception->throw($tx->res->code) unless $tx->res->is_success;

  return $tx->res;
}

sub _ua {
  my $self = shift;

  my $ua = Mojo::UserAgent->new(insecure => 1);
  $ua->transactor->name("Podman/$VERSION");
  if ($self->_connection_url->scheme eq 'http+unix') {
    $ua->proxy->http($self->_connection_url->scheme . '://' . url_escape($self->_connection_url->path));
  }

  return $ua;
}

1;

__END__