File Coverage

blib/lib/Pod/Pandoc/Modules.pm

Criterion	Covered	Total	%
statement	47	89	52.8
branch	2	28	7.1
condition	2	20	10.0
subroutine	13	17	76.4
pod	2	5	40.0
total	66	159	41.5

package Pod::Pandoc::Modules;
use strict;
use warnings;
use 5.010;

our $VERSION = '0.30';

use File::Path qw(make_path);
use File::Find;
use File::Spec;
use File::stat;
use File::Basename qw(dirname);
use Pandoc::Elements;
use Carp qw(croak);

sub new {
    bless( ( $_[1] // {} ), $_[0] );
}

sub add {
    my ( $self, $name, $doc ) = @_;

    # TODO: don't override .pod with .pm
    if ( $self->{$name} ) {
        return;
    }
    else {
        $self->{$name} = $doc;
    }
}

sub module_link {
    my ( $module, $opt ) = @_;
    if ( $opt->{wiki} ) {
        my $target = $module;
        $target =~ s{::}{-}g;
        return Link attributes {}, [ Str $module ], [ $target, 'wikilink' ];
    }
    else {
        my $name = shift;
        my $file = $name;
        $file =~ s{::}{/}g;
        $file .= '.' . ( $opt->{ext} // 'html' );
        return Link attributes {}, [ Str $name ], [ $file, $name ];
    }
}

sub index {
    my ( $modules, %opt ) = @_;

    # TODO: extend, document, and test metadata
    my %meta = map { $_ => MetaString "" . $opt{$_} }
      grep { defined $opt{$_} } qw{title};

    my @definitions = map {
        [
            [ module_link( $_, \%opt ) ],
            [ [ Plain [ Str $modules->{$_}->metavalue('subtitle') ] ] ]
        ]
    } sort keys %$modules;

    Document \%meta, [ DefinitionList \@definitions ];
}

sub serialize {
    my ( $modules, $dir, $opt, @args ) = _parse_arguments(@_);

    # adjust links
    # TODO: create copy instead of transforming, so
    # this can be called multiple times!
    foreach my $doc ( values %$modules ) {
        $doc->transform(
            Link => sub {

                # TODO: use configured prefix instead of hard-coded URL base
                my ( $module, $hash ) =
                  $_->url =~ qr{^https://metacpan\.org/pod/([^#]+)(#.*)?$};
                return unless ( $module and $modules->{$module} );

                # TODO: check whether hash link target exists
                my $link = module_link( $module, $opt );
                if ( defined $hash ) {
                    $link->url( $link->url . $hash );
                }
                return $link;
            }
        );
    }

    # serialize
    foreach my $doc ( values %$modules ) {
        my $file   = $doc->metavalue('file');
        my $module = $doc->metavalue('title');

        my $name = $module;
        if ( $opt->{wiki} ) {
            $name =~ s{::}{-}g;
        }
        else {
            $name =~ s{::}{/}g;
        }
        $name .= '.' . ( $opt->{ext} // 'html' );
        my $target = File::Spec->catfile( $dir, $name );

        if ( $opt->{update} and -e $target ) {
            next if stat($file)->[9] <= stat($target)->[9];
        }

        make_path( dirname($target) );
        $doc->to_pandoc( -o => $target, @args );
        say "$file => $target" unless $opt->{quiet};
    }

    # create index file
    if ( $opt->{index} ) {
        my $index = $modules->index(%$opt);
        my $target =
          File::Spec->catfile( $dir, $opt->{index} . '.' . $opt->{ext} );
        $index->to_pandoc( @args, -o => $target );
        say $target unless $opt->{quiet};
    }
}

sub _parse_arguments {
    my $modules = shift;

    my $dir = ref $_[0] ? undef        : shift;
    my %opt = ref $_[0] ? %{ shift() } : ();

    $dir //= $opt{dir} // croak "output directory must be specified!";
    $opt{index} = 'index' unless exists $opt{index};

    $opt{ext} //= 'html';
    $opt{ext} =~ s/^\.//;
    croak "ext must not be .pm or .pod" if $opt{ext} =~ /^(pod|pm)$/;

    ( $modules, $dir, \%opt, @_ );
}

1;
__END__