File Coverage

blib/lib/Plack/Middleware/TrailingSlashKiller.pm

Criterion	Covered	Total	%
statement	20	20	100.0
branch	7	8	87.5
condition	3	3	100.0
subroutine	5	5	100.0
pod	1	1	100.0
total	36	37	97.3

package Plack::Middleware::TrailingSlashKiller;

use strict;
use warnings;
use parent qw(Plack::Middleware);

use Plack::Util::Accessor qw( redirect );

our $VERSION  = '0.01';
our %STATUSES = (
   301 => 'Moved Permanently',
   307 => 'Temporary Redirect',
);

sub call {
    my( $self, $env ) = @_;

    # check for/replace trailing slash
    if( $env->{PATH_INFO} =~ s{^(.+)/$}{$1} ) {
        # redirect if waned
        if( $self->redirect ) {
            my $code = ( $env->{REQUEST_METHOD } eq 'HEAD' ||
                         $env->{REQUEST_METHOD } eq 'GET' )
                     ? 301
                     : 307;
            my $location = $env->{PATH_INFO};
               $location .= "?$env->{QUERY_STRING}" if $env->{QUERY_STRING};

            return [ $code, [ 'Location' => $location ], [ $STATUSES{$code} ] ];
        }
    }

    # return the app's content (with possibly updated PATH_INFO)
    return $self->app->($env);
}

1;
__END__