File Coverage

blib/lib/Plack/Middleware/ServerTiming.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	6	6	100.0
condition	2	3	66.6
subroutine	7	7	100.0
pod	1	1	100.0
total	49	50	98.0

package Plack::Middleware::ServerTiming;
use strict;
use warnings;
use parent qw/Plack::Middleware/;
use Plack::Util;

our $VERSION = "0.04";

sub call {
    my ($self, $env) = @_;

    my $res = $self->app->($env);
    $self->response_cb($res, sub {
        my $res = shift;

        return unless exists $env->{'psgix.server-timing'};

        my @header;
        for my $metric (@{$env->{'psgix.server-timing'}}) {
            my $name  = $metric->[0];
            my %field = %{$metric->[1] || {}};
            my @opt = map { "$_=" . _escape($field{$_}) } grep { defined $field{$_} } qw/dur desc/;
            push @header, join ';', $name, @opt;
        }
        Plack::Util::header_set($res->[1], 'Server-Timing', join(', ', @header));
    });
}

sub _escape {
    my $v = shift;
    if ($v =~ /[\x00-\x20()<>@,;:\\\"\/\[\]?={}\x7F-\xFF]/ || !length($v)) {
        $v =~ s/([\"\\])/\\$1/g;
        return qq{"$v"};
    } else {
        return $v;
    }
}

1;
__END__