File Coverage

blib/lib/Plack/Middleware/Rewrite/Query.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	4	4	100.0
condition			n/a
subroutine	9	9	100.0
pod	3	3	100.0
total	58	58	100.0

use strict;
package Plack::Middleware::Rewrite::Query;
#ABSTRACT: Safely modify the QUERY_STRING of a PSGI request
our $VERSION = '0.1.1'; #VERSION

use parent qw(Plack::Middleware Exporter);
use Plack::Util::Accessor qw(map modify);
use Plack::Request ();
use URI::Escape ();
use Hash::MultiValue;

our @EXPORT_OK = qw(rewrite_query query_string);

sub call {
    my ($self, $env) = @_;
    rewrite_query($env, modify => $self->modify, map => $self->map);
    $self->app->($env);
}

sub rewrite_query {
    my ($env, %config) = @_;

    my $query  = Plack::Request->new($env)->query_parameters;
    my $map    = $config{map};
    my $modify = $config{modify};

    if ($map) {
        my @keys   = $query->keys;
        my @values = $query->values;
        $query->clear;
        $query->merge_flat(
            map { $map->($keys[$_], $values[$_]) } 0 .. $#keys
        );

    }

    if ($modify) {
        map { $modify->($_) } $query; # alias $_ to $query
    }

    # rebuild QUERY_STRING
    $env->{QUERY_STRING} = query_string($query);

    # this has become invalid if it existed
    delete $env->{'plack.request.merged'};
}

sub query_string {
    my ($query) = @_;
    my @values = map { URI::Escape::uri_escape($_) } $query->values;
    join '&', map {
         $_ . '=' . shift @values
    } map { URI::Escape::uri_escape($_) } $query->keys;
}

1;

__END__