File Coverage

blib/lib/Plack/Middleware/RevisionPlate.pm

Criterion	Covered	Total	%
statement	50	50	100.0
branch	12	14	85.7
condition	11	14	78.5
subroutine	12	12	100.0
pod	2	2	100.0
total	87	92	94.5

package Plack::Middleware::RevisionPlate;
use 5.010;
use strict;
use warnings;

use Plack::Util::Accessor qw/path revision_filename/;
use Plack::Response;
use File::Slurp qw/read_file/;
use parent qw/Plack::Middleware/;

our $VERSION = "0.01";

sub call {
    my $self = shift;
    my $env  = shift;
    return $self->_may_handle_request($env) // $self->app->($env);
}

sub prepare_app {
    my $self = shift;
    $self->_read_revision_file_at_first;
}

sub _read_revision_file_at_first {
    my $self = shift;
    $self->{revision} = -e $self->_revision_filename && read_file($self->_revision_filename);
}

sub _may_handle_request {
    my ($self, $env) = @_;
    my $path_match = $self->path or return;
    my $path = $env->{PATH_INFO};

    for ($path) {
        my $matched = 'CODE' eq ref $path_match ? $path_match->($_, $env) : $_ =~ $path_match;
        return unless $matched;
    }

    my $method = $env->{REQUEST_METHOD};
    return Plack::Response->new(405)->finalize if $method ne 'GET' && $method ne 'HEAD'; # 405: method not allowed

    my $res = Plack::Response->new;
    $res->content_type('text/plain');
    if (defined $self->{revision}) {
        if (-e $self->_revision_filename) {
            $res->status(200);
            $res->body($self->{revision});
        } else {
            $res->status(404);
            $res->body("REVISION_FILE_REMOVED\n");
        }
    } else {
        $res->status(404);
        $res->body("REVISION_FILE_NOT_FOUND\n");
    }

    $res->body('') if $method eq 'HEAD';
    return $res->finalize;
}

sub _revision_filename {
    my $self = shift;
    $self->{_revision_filename} //= $self->revision_filename // './REVISION';
}

1;
__END__