File Coverage

blib/lib/Plack/Middleware/RequestId.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	12	12	100.0
condition	5	6	83.3
subroutine	9	9	100.0
pod	2	2	100.0
total	66	67	98.5

package Plack::Middleware::RequestId;
use strict;
use warnings;

use parent 'Plack::Middleware';
use Plack::Util;
use Plack::Util::Accessor qw/
    psgi_env_key
    http_header
    req_http_header
    id_generator
    force_generate_id
    env_key
    no_http_header
/;

our $VERSION = '0.07';

our $request_id;

sub prepare_app {
    my ($self) = @_;

    unless ($self->psgi_env_key) {
        $self->psgi_env_key('psgix.request_id');
    }

    unless ($self->http_header) {
        $self->http_header('X-Request-Id');
    }

    my $req_http_header = 'HTTP_'. uc $self->http_header;
    $req_http_header =~ s/-/_/g;
    $self->req_http_header($req_http_header);

    unless ($self->id_generator) {
        require Data::UUID;
        Data::UUID->import;
        $self->{_uuid_obj} = Data::UUID->new;
        $self->id_generator(sub {
            substr $self->{_uuid_obj}->create_hex, 2, 32;
        });
    }
}

sub call {
    my($self, $env) = @_;

    $request_id
        = $env->{$self->psgi_env_key}
            = (!$self->force_generate_id && $env->{$self->req_http_header})
            ? $env->{$self->req_http_header}
            : $self->id_generator->($env);

    if ($self->env_key) {
        $ENV{$self->env_key} = $request_id;
    }

    my $res = $self->app->($env);

    $self->response_cb($res, sub {
        my $res = shift;
        if ($res && !$self->no_http_header) {
            Plack::Util::header_push(
                $res->[1],
                $self->http_header,
                $env->{$self->psgi_env_key},
            );
        }
    });
}

1;

__END__