File Coverage

blib/lib/Plack/Middleware/PostErrorToSlack.pm

Criterion	Covered	Total	%
statement	54	56	96.4
branch	6	8	75.0
condition			n/a
subroutine	14	14	100.0
pod	1	3	33.3
total	75	81	92.5

package Plack::Middleware::PostErrorToSlack;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.01";

use Plack::Util::Accessor qw(webhook_url channel username icon_url icon_emoji);

use parent qw(Plack::Middleware);

use Plack::Response;
use Try::Tiny;

use LWP::UserAgent;
use JSON::XS qw(encode_json);

sub call {
    my $self = shift;
    my $env = shift;

    my $error;
    my $res = try {
        $self->app->($env);
    } catch {
        $error = $_;
    };
    if ($error) {
        $self->post_error($env, $error);
        die $error;
    }

    return $res;
}

sub post_error {
    my ($self, $env, $error) = @_;

    my $message = $self->error_message($env, $error);

    my $ua = LWP::UserAgent->new;

    unless ($self->webhook_url) {
        warn 'Please set webhook_url';
    }

    my $payload = {
        text       => $message,
    };
    for my $key (qw{channel username icon_url icon_emoji}) {
        my $value = $self->$key;
        next unless $value;
        $payload->{$key} = $value;
    }

    $ua->post($self->webhook_url, {
        payload => encode_json($payload),
    });
}

sub error_message {
    my ($self, $env, $error) = @_;

    my $user = $ENV{'USER'};

    my $branch = `git rev-parse --abbrev-ref HEAD`;
    chomp $branch;

    $error = $error . ''; # copy;
    chomp $error;

    if ($branch) {
        sprintf "%s encountered an error while `%s %s` on branch `%s`\n```\n%s\n```", $user, $env->{REQUEST_METHOD}, $env->{PATH_INFO}, $branch, $error;
    } else {
        sprintf "%s encountered an error while `%s %s`\n```\n%s\n```", $user, $env->{REQUEST_METHOD}, $env->{PATH_INFO}, $error;
    }
}

1;

__END__