File Coverage

blib/lib/Plack/Middleware/Pjax.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	8	8	100.0
condition	2	2	100.0
subroutine	8	8	100.0
pod	1	1	100.0
total	60	60	100.0

#
# This file is part of Plack-Middleware-Pjax
#
# This software is copyright (c) 2011 by Matthew Phillips.
#
# This is free software; you can redistribute it and/or modify it under
# the same terms as the Perl 5 programming language system itself.
#
use strict;
use warnings;

package Plack::Middleware::Pjax;
{
  $Plack::Middleware::Pjax::VERSION = '1.113400';
}
# ABSTRACT: PJAX for your Plack
use parent qw/Plack::Middleware/;


use Plack::Util;
use Plack::Request;
use Marpa::HTML;

sub call {
    my ($self, $env) = @_;

    my $res = $self->app->($env);

    Plack::Util::response_cb($res, sub {
        my $req = Plack::Request->new($env);
        my $res = shift;

        return unless defined $req->header('x-pjax');
        my $tag = $req->header('x-pjax-container') || 'data-pjax-container';

        my $body = [];
        Plack::Util::foreach($res->[2], sub { push @$body, $_[0]; });
        $body = join '', @$body;

        my $stripped = Marpa::HTML::html( \$body,{
            q{*} => sub {
                if (Marpa::HTML::attributes()->{$tag}) {
                    push @{$Marpa::HTML::INSTANCE->{stripped}}, Marpa::HTML::contents();
                }
            },
            q{title} => sub {
                unshift @{$Marpa::HTML::INSTANCE->{stripped}}, Marpa::HTML::original();
            },
            ':TOP' => sub {
                $Marpa::HTML::INSTANCE->{stripped} || [];
            }
        });

        # if length is 0 or 1, there was no pjax container in the body,
        #  so just return the original
        if (@$stripped > 0) {
            $res->[2] = [join '', @$stripped];
            my $h = Plack::Util::headers($res->[1]);
            # recalculate content length after changing it
            $h->set('Content-Length', Plack::Util::content_length($res->[2]));
        }

        return $res;
    });
}

1;

__END__