File Coverage

blib/lib/Plack/Middleware/Antibot/TextCaptcha.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	4	6	66.6
condition	8	14	57.1
subroutine	7	7	100.0
pod	2	2	100.0
total	59	67	88.0

package Plack::Middleware::Antibot::TextCaptcha;

use strict;
use warnings;

use parent 'Plack::Middleware::Antibot::FilterBase';

use Plack::Session;
use Plack::Request;

sub new {
    my $self = shift->SUPER::new(@_);
    my (%params) = @_;

    $self->{session_name} = $params{session_name} || 'antibot_textcaptcha';
    $self->{field_name}   = $params{field_name}   || 'antibot_textcaptcha';
    $self->{variants} = $params{variants} || [{text => '2 + 2', answer => 4}];
    $self->{score}    = $params{score}    || 0.9;

    return $self;
}

sub execute {
    my $self = shift;
    my ($env) = @_;

    my $variants = $self->{variants};

    my $captcha = $variants->[int(rand(@$variants))];
    $env->{'plack.antibot.textcaptcha.text'}       = $captcha->{text};
    $env->{'plack.antibot.textcaptcha.field_name'} = $self->{field_name};

    if ($env->{REQUEST_METHOD} eq 'GET') {
        my $session = Plack::Session->new($env);
        $session->set($self->{session_name}, $captcha->{answer});
    }
    elsif ($env->{REQUEST_METHOD} eq 'POST') {
        my $session = Plack::Session->new($env);

        my $expected = $session->get($self->{session_name});
        my $got      = Plack::Request->new($env)->param($self->{field_name});

        unless ($expected && $got && $got eq $expected) {
            $env->{'plack.antibot.textcaptcha.detected'}++;
        }

        $session->set($self->{session_name}, $captcha->{answer});
    }

    return;
}

1;
__END__