File Coverage

blib/lib/Plack/Component/Tags/HTML.pm

Criterion	Covered	Total	%
statement	90	92	97.8
branch	29	34	85.2
condition	3	6	50.0
subroutine	20	20	100.0
pod	2	2	100.0
total	144	154	93.5

package Plack::Component::Tags::HTML;

use base qw(Plack::Component);
use strict;
use warnings;

use CSS::Struct::Output::Raw;
use Encode qw(encode);
use Error::Pure qw(err);
use Plack::Util::Accessor qw(author content_type css css_init encoding
	favicon flag_begin flag_end generator psgi_app script_js script_js_src
	status_code title tags);
use Scalar::Util qw(blessed);
use Tags::HTML::Page::Begin;
use Tags::HTML::Page::End;
use Tags::Output::Raw;

our $VERSION = 0.15;

sub call {
	my ($self, $env) = @_;

	# Process actions.
	$self->_process_actions($env);

	# PSGI application.
	if ($self->psgi_app) {
		my $app = $self->psgi_app;
		$self->psgi_app(undef);
		return $app;
	}

	# Process 'CSS::Struct' for page.
	if (defined $self->{'_page_begin'}) {
		$self->{'_page_begin'}->process_css;
	}
	$self->_css($env);

	# Process 'Tags' for page.
	$self->_tags($env);
	$self->tags->finalize;
	$self->_cleanup($env);

	return [
		$self->status_code,
		[
			'content-type' => $self->content_type,
		],
		[$self->_encode($self->tags->flush(1))],
	];
}

sub prepare_app {
	my $self = shift;

	$self->_prepare_app;

	return;
}

sub _cleanup {
	my ($self, $env) = @_;

	return;
}

sub _css {
	my ($self, $env) = @_;

	return;
}

sub _encode {
	my ($self, $string) = @_;

	return encode($self->encoding, $string);
}

sub _prepare_app {
	my $self = shift;

	if ($self->tags) {
		if (! blessed($self->tags) || ! $self->tags->isa('Tags::Output')) {
			err "Accessor 'tags' must be a 'Tags::Output' object.";
		}
	} else {
		$self->tags(Tags::Output::Raw->new(
			'xml' => 1,
			'no_simple' => ['script', 'textarea'],
			'preserved' => ['pre', 'style'],
		));
	}

	if ($self->css) {
		if (! blessed($self->css) || ! $self->css->isa('CSS::Struct::Output')) {
			err "Accessor 'css' must be a 'CSS::Struct::Output' object.";
		}
	} else {
		$self->css(CSS::Struct::Output::Raw->new);
	}

	if (! $self->encoding) {
		$self->encoding('utf-8');
	}

	if (! $self->content_type) {
		$self->content_type('text/html; charset='.$self->encoding);
	}

	if (! $self->status_code) {
		$self->status_code(200);
	}

	if (! defined $self->flag_begin) {
		$self->flag_begin(1);
	}

	if (! defined $self->flag_end) {
		$self->flag_end(1);
	}

	if (! defined $self->script_js) {
		$self->script_js([]);
	}

	if (! defined $self->script_js_src) {
		$self->script_js_src([]);
	}

	if ($self->flag_begin) {
		$self->{'_page_begin'} = Tags::HTML::Page::Begin->new(
			'author' => $self->author,
			'css' => $self->css,
			defined $self->css_init ? (
				'css_init' => $self->css_init,
			) : (),
			'charset' => $self->encoding,
			'favicon' => $self->favicon,
			'generator' => $self->generator,
			'lang' => {
				'title' => $self->title,
			},
			'script_js' => $self->script_js,
			'script_js_src' => $self->script_js_src,
			'tags' => $self->tags,
		);
	}

	return;
}

sub _process_actions {
	my ($self, $env) = @_;

	return;
}

sub _tags_middle {
	my ($self, $env) = @_;

	return;
}

sub _tags {
	my ($self, $env)= @_;

	if ($self->flag_begin) {
		$self->{'_page_begin'}->process;
	}

	$self->_tags_middle($env);

	if ($self->flag_end) {
		Tags::HTML::Page::End->new(
			'tags' => $self->tags,
		)->process;
	}

	return;
}

1;

__END__