File Coverage

blib/lib/Plack/App/CGIBin/Streaming/IO.pm

Criterion	Covered	Total	%
statement	21	24	87.5
branch	5	10	50.0
condition	2	6	33.3
subroutine	9	10	90.0
pod	0	2	0.0
total	37	52	71.1

package Plack::App::CGIBin::Streaming::IO;

use 5.014;
use strict;
use warnings;
use Plack::App::CGIBin::Streaming;

sub PUSHED {
    #my ($class, $mode, $fh) = @_;

    return bless +{read_mode => (substr($_[1], 0, 1) eq 'r')}, $_[0];
}

sub WRITE {
    #my ($self, $buf, $fh) = @_;

    $Plack::App::CGIBin::Streaming::R->print_content($_[1]);
    return length $_[1];
}

sub FLUSH {
    #my ($self, $fh) = @_;

    return 0 if $_[0]->{in_flush} or $_[0]->{read_mode};
    local $_[0]->{in_flush}=1;

    $Plack::App::CGIBin::Streaming::R->flush
        unless $Plack::App::CGIBin::Streaming::R->suppress_flush;

    return 0;
}

sub READ {
    #my ($self, $buf, $len, $fh) = @_;

    return $_[3]->read($_[1], $_[2]);
}

sub SEEK {
    #my ($self, $pos, $whence, $fh) = @_;

    return -1
        unless ($_[0]->{read_mode} and
                $Plack::App::CGIBin::Streaming::R->env->{'psgix.input.buffered'});

    return $_[3]->seek($_[1], $_[2]) ? 0 : -1;
}

sub BINMODE {
    #my ($self, $fh) = @_;

    # pop the layer when we are done
    return if $Plack::App::CGIBin::Streaming::R->binmode_ok;

    # otherwise keep it
    return 0;
}

1;

__END__