File Coverage

blib/lib/PerlX/Let.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	13	14	92.8
condition	5	6	83.3
subroutine	9	9	100.0
pod			n/a
total	68	70	97.1

package PerlX::Let;

# ABSTRACT: Syntactic sugar for lexical state constants

use v5.12;

use strict;
use warnings;

use Const::Fast ();
use Keyword::Simple 0.04;
use Text::Balanced ();

our $VERSION = 'v0.2.7';


sub import {
    Keyword::Simple::define 'let', \&_rewrite_let;
}

sub unimport {
    Keyword::Simple::undefine 'let';
}

sub _rewrite_let {
    my ($ref) = @_;

    my $let = "";

    do {

        my ( $name, $val );

        ( $name, $$ref ) = Text::Balanced::extract_variable($$ref);
        die "A variable name is required for let" unless defined $name;
        $$ref =~ s/^\s*\=>?\s*// or die "An assignment is required for let";
        ( $val, $$ref ) = Text::Balanced::extract_quotelike($$ref);
        ( $val, $$ref ) = Text::Balanced::extract_bracketed( $$ref, '({[' )
          unless defined $val;

        unless ( defined $val ) {
            ($val) = $$ref =~ /^(\S+)/;
            $$ref =~ s/^\S+//;
        }

        die "A value is required for let" unless defined $val;

        if ($val !~ /[\$\@\%\&]/ && ($] >= 5.028 || substr($name, 0, 1) eq '$')) {

            # We can't use Const::Fast on state variables, so we use
            # this workaround.

            $let .= "use feature 'state'; state $name = $val; unless (state \$__perlx_let_state_is_set = 0) { Const::Fast::_make_readonly(\\$name); \$__perlx_let_state_is_set = 1; };";

        }
        else {

            $let .= "Const::Fast::const my $name => $val; ";
        }

    } while ( $$ref =~ s/^\s*,\s*// );

    my $code;

    ( $code, $$ref ) = Text::Balanced::extract_codeblock( $$ref, '{' );

    if ($code) {
        substr( $code, index( $code, '{' ) + 1, 0 ) = $let;
        substr( $$ref, 0, 0 ) = $code;
    }
    else {
        substr( $$ref, 0, 0 ) = $let;
    }

}



1;

__END__