File Coverage

blib/lib/PerlIO/via/ANSIColor.pm

Criterion	Covered	Total	%
statement	8	35	22.8
branch	0	16	0.0
condition			n/a
subroutine	3	8	37.5
pod	4	4	100.0
total	15	63	23.8

package PerlIO::via::ANSIColor;

use strict;
use warnings;
require Term::ANSIColor;

our $VERSION = '0.05';
my $color = 'red';
my $reset = Term::ANSIColor::color('reset');

sub import {
    my( $class, %param ) = @_;
    $class->$_( $param{$_} ) foreach keys %param;
}

sub color {
    my $self      = shift;
    my $new_color = shift;
    if ( defined $new_color ) {
        eval { Term::ANSIColor::color($new_color) };
        $color = $new_color unless $@;
    }
    return $color;
}

sub paint {
    my $self      = shift;
    my $fh        = shift;
    my $new_color = shift;
    return unless $fh;
    $self->color($new_color) if $new_color;
    binmode $fh, ':via(ANSIColor)';
}

sub PUSHED {
    bless { color => Term::ANSIColor::color($color) }, $_[0];
}

sub FILL {
    my $color = $_[0]->{color};
    if ( defined( my $line = readline( $_[1] ) ) ) {
        return $color . $line . $reset;
    }
    undef;
}

sub WRITE {
    my $color = $_[0]->{color};
    my $str   = $_[1];
    if ($str =~ /\n$/ ) {
        chomp $str;
        print { $_[2] } $color . $str . $reset . "\n" or return -1;
    }
    else {
        print { $_[2] } $color . $_[1] . $reset or return -1;
    }
    length $_[1];
}

1;

__END__