File Coverage

blib/lib/Perinci/Object/EnvResultMulti.pm

Criterion	Covered	Total	%
statement	57	57	100.0
branch	10	10	100.0
condition	6	10	60.0
subroutine	6	6	100.0
pod	2	2	100.0
total	81	85	95.2

package Perinci::Object::EnvResultMulti;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2021-01-02'; # DATE
our $DIST = 'Perinci-Object'; # DIST
our $VERSION = '0.311'; # VERSION

use 5.010;
use strict;
use warnings;

use parent qw(Perinci::Object::EnvResult);

sub new {
    my ($class, $res) = @_;
    $res //= [200, "Success/no items"];
    my $obj = \$res;
    bless $obj, $class;
}

sub add_result {
    my ($self, $status, $message, $extra) = @_;
    $extra //= {};
    my $num_ok  = 0;
    my $num_nok = 0;

    push @{ ${$self}->[3]{results} },
        {status=>$status, message=>$message, %$extra};
    if (exists $extra->{payload}) {
        ${$self}->[2] //= [];
        push @{ ${$self}->[2] }, $extra->{payload};
    }
    for (@{ ${$self}->[3]{results} // [] }) {
        if ($_->{status} =~ /\A(2|304)/) {
            $num_ok++;
        } else {
            $num_nok++;
        }
    }
    if ($num_ok) {
        if ($num_nok) {
            ${$self}->[0] = 207;
            ${$self}->[1] = "Partial success";
        } else {
            my $overall_status = 200;
            my %statuses;
            for (@{ ${$self}->[3]{results} // []}) {
                $statuses{ $_->{status} }++;
            }
            if (keys %statuses == 1) {
                my @tmp = keys %statuses;
                $overall_status = $tmp[0];
            }
            ${$self}->[0] = $overall_status;
            ${$self}->[1] = "All success";
        }
    } else {
        ${$self}->[0] = $status;
        ${$self}->[1] = $message;
    }
}

1;
# ABSTRACT: Represent enveloped result (multistatus)

__END__