File Coverage

blib/lib/Path/Trim.pm

Criterion	Covered	Total	%
statement	47	47	100.0
branch	16	16	100.0
condition	7	7	100.0
subroutine	11	11	100.0
pod	8	8	100.0
total	89	89	100.0

package Path::Trim;

use warnings;
use strict;

use version; our $VERSION = qv('0.0.3');

sub new {
    return bless {}, __PACKAGE__;
}

sub get_current_directory {
    my $self = shift;
    return $self->{'current_directory'} || '.';
}

sub set_current_directory {
    my ( $self, $current_directory ) = @_;
    return $self->{'current_directory'} = $current_directory;
}

sub get_parent_directory {
    my $self = shift;
    return $self->{'parent_directory'} || '..';
}

sub set_parent_directory {
    my ( $self, $parent_directory ) = @_;
    return $self->{'parent_directory'} = $parent_directory;
}

sub get_directory_separator {
    my $self = shift;
    return $self->{'directory_separator'};
}

sub set_directory_separator {
    my ( $self, $directory_separator ) = @_;
    return $self->{'directory_separator'} = $directory_separator;
}

sub trim_path {
    my ( $self, $path ) = @_;
    my $current_directory   = $self->get_current_directory();
    my $parent_directory    = $self->get_parent_directory();
    my $directory_separator = $self->get_directory_separator();
    my ( $left_stripped, $right_stripped );
    if ( $path =~ s/^\Q$directory_separator\E// ) {
        $left_stripped = 1;
    }
    if ( $path =~ s/\Q$directory_separator\E$// ) {
        $right_stripped = 1;
    }
    my @dirs = split /\Q$directory_separator\E/, $path;
    my @new_path;

    for my $dir (@dirs) {
        if ( $dir eq $parent_directory ) {
            if ( @new_path && $new_path[-1] ne $parent_directory ) {
                pop @new_path;
            }
            else {
                push @new_path, $parent_directory;
            }
        }
        elsif ( $dir ne $current_directory ) {
            push @new_path, $dir;
        }
    }

    if ( !@new_path ) {
        push @new_path, $current_directory;
    }

    my $new_path = join $directory_separator, @new_path;
    if ($left_stripped) {
        $new_path = $directory_separator . $new_path;
    }
    if ($right_stripped) {
        $new_path = $new_path . $directory_separator;
    }
    return $new_path;
}

1;
__END__