File Coverage

blib/lib/Path/Tiny/Archive/Tar.pm

Criterion	Covered	Total	%
statement	49	50	98.0
branch	12	20	60.0
condition			n/a
subroutine	11	11	100.0
pod	2	2	100.0
total	74	83	89.1

package Path::Tiny::Archive::Tar;

# ABSTRACT: Tar/untar add-on for file path utility

use strict;
use warnings;

use Archive::Tar qw( COMPRESS_GZIP COMPRESS_BZIP );
use Compress::Raw::Zlib qw( :level );
use Path::Tiny qw( path );

use namespace::clean;

use Exporter qw( import );


our $VERSION = '0.001';

our %EXPORT_TAGS = ( const =>[qw(
    COMPRESSION_NONE
    COMPRESSION_GZIP
    COMPRESSION_GZIP_DEFAULT
    COMPRESSION_GZIP_NONE
    COMPRESSION_GZIP_FASTEST
    COMPRESSION_GZIP_BEST
    COMPRESSION_BZIP2
)] );
our @EXPORT_OK = @{ $EXPORT_TAGS{const} };


BEGIN {
    push(@Path::Tiny::ISA, __PACKAGE__);
}

use constant {
    COMPRESSION_NONE         => undef,
    COMPRESSION_GZIP         => COMPRESS_GZIP,
    COMPRESSION_GZIP_DEFAULT => Z_DEFAULT_COMPRESSION,
    COMPRESSION_GZIP_NONE    => Z_NO_COMPRESSION,
    COMPRESSION_GZIP_FASTEST => Z_BEST_SPEED,
    COMPRESSION_GZIP_BEST    => Z_BEST_COMPRESSION,
    COMPRESSION_BZIP2        => COMPRESS_BZIP,
};


sub tar {
    my ($self, $dest, $level) = @_;

    $dest = path($dest);

    my $tar = Archive::Tar->new;

    if ($self->is_file) {
        my $file = Archive::Tar::File->new(file => $self->stringify());

        return unless $file;

        $file->name($self->basename);
        $file->prefix('');

        $tar->add_files($file) or return;
    }
    elsif ($self->is_dir) {
        my $paths = $self->iterator({ recurse => 1 });

        while (my $path = $paths->()) {
            my $file = Archive::Tar::File->new(file => $path->stringify());

            return unless $file;

            $file->rename($path->relative($self));

            $tar->add_files($file) or return;
        }
    }
    else {
        return;
    }

    $tar->write($dest->stringify(), defined $level ? $level : ()) or return;

    return $dest;
}


sub untar {
    my ($self, $dest) = @_;

    $dest = path($dest);

    my $files = Archive::Tar->iter($self->stringify());

    return unless $files;

    while (my $file = $files->()) {
        $file->extract($dest->child($file->full_path)->stringify()) or return;
    }

    return $dest;
}


1;

__END__