File Coverage

blib/lib/Package/Rename.pm

Criterion	Covered	Total	%
statement	40	46	86.9
branch	2	2	100.0
condition			n/a
subroutine	11	12	91.6
pod	4	4	100.0
total	57	64	89.0

package Package::Rename;

use strict;
use warnings;
use Carp;
use MRO::Compat;
use base 'Exporter';
our @EXPORT_OK = qw/copy_package remove_package rename_package link_package/;

our $VERSION = '0.02';

sub copy_package {
	my ($old_name, $new_name) = @_;
	no strict 'refs';
	%{"$new_name\::"} = %{"$old_name\::"};
	mro::method_changed_in($new_name);
	return;
}

sub remove_package {
	my $name = shift;
	my ($super, $sub) = $name =~ / ^ ( \w+ (?> ::\w+ )* ) :: (\w+) $/xs ? ($1, $2) : ('main', $name);
	no strict 'refs';
	undef ${"$super\::"}{"$sub\::"};
	mro::method_changed_in($name);
	return;
}

sub link_package {
	my ($old_name, $new_name) = @_;
	no strict 'refs';
	*{"$new_name\::"} = *{"$old_name\::"};
	mro::method_changed_in($new_name);
	return;
}

sub rename_package {
	my ($old_name, $new_name) = @_;
	link_package($old_name, $new_name);
	remove_package($old_name);
	return;
}

1;    # End of Package::Rename

__END__