File Coverage

blib/lib/POE/Filter/LZW/Progressive.pm

Criterion	Covered	Total	%
statement	32	51	62.7
branch	4	18	22.2
condition	1	3	33.3
subroutine	7	12	58.3
pod	0	8	0.0
total	44	92	47.8

package POE::Filter::LZW::Progressive;

use strict;
use warnings;

use Compress::LZW::Progressive;
use base qw(POE::Filter);

our $VERSION = '0.1';

sub new {
	my ($class, %args) = @_;
	# Filter passthru args to just those that are pertinent
	my %passthru_args = map { $_ => $args{$_} } grep { /^(bits)$/ } keys %args;
	$args{codec} ||= Compress::LZW::Progressive->new(%passthru_args);

	$args{buffer} = '';
	return bless \%args, ref $class ? ref $class : $class;
}

sub reset {
	my $self = shift;
	$self->{codec}->reset();
}

sub clone {
	my $self = shift;
	return $self->new();
}

##

sub get {
	my ($self, $raw_lines) = @_;

	my @records;
	foreach my $line (@$raw_lines) {
		my $decompressed = $self->{codec}->decompress($line);
		push @records, $decompressed;
		printf STDERR "POE::Filter::LZW::Progressive get():  decompressed %d B to %d B\n",
			length($line), length($decompressed) if $self->{debug};
	}
	printf STDERR "POE::Filter::LZW::Progressive get(): returning %d records\n", int(@records) if $self->{debug};
	return \@records;
}

sub get_one_start {
	my ($self, $raw_lines) = @_;

	$self->{buffer} .= join '', @$raw_lines;
	printf STDERR "POE::Filter::LZW::Progressive get_one_start(): buffer now %d\n", length($self->{buffer}) if $self->{debug} > 1;
}

sub get_one {
	my $self = shift;
	return [] unless length $self->{buffer};

	my $return = [ $self->{codec}->decompress( $self->{buffer} ) ];
	printf STDERR "POE::Filter::LZW::Progressive get_one():  decompressed %d B to %d B (%s)\n",
		length($self->{buffer}), length($return->[0]), $self->{codec}->stats('decompress') if $self->{debug};

	$self->{buffer} = '';
	return $return;
}

# Same as get_one() but doesn't clear the buffer
sub get_pending {
	my $self = shift;
	printf STDERR "POE::Filter::LZW::Progressive get_pending()\n" if $self->{debug} > 1;
	return undef unless length $self->{buffer};
	return [ $self->{codec}->decompress( $self->{buffer} ) ];
}

sub put {
	my ($self, $records) = @_;

	my @raw_lines;
	foreach my $record (@$records) {
		my $compressed = $self->{codec}->compress($record);
		push @raw_lines, $compressed;
		print STDERR "POE::Filter::LZW::Progressive put(): ".$self->{codec}->stats('compress')."\n" if $self->{debug};
	}
	return \@raw_lines;
}

1;

__END__