File Coverage

blib/lib/POE/Component/Net/FTP.pm

Criterion	Covered	Total	%
statement	19	56	33.9
branch	0	28	0.0
condition	0	13	0.0
subroutine	7	11	63.6
pod	1	1	100.0
total	27	109	24.7

package POE::Component::Net::FTP;

use warnings;
use strict;

our $VERSION = '0.001';

use Carp;
use POE;
use Net::FTP;
use base 'POE::Component::NonBlockingWrapper::Base';

my %True_False_Commands = map { $_ => 1 }
    qw( new  login  authorize  ascii  binary  rename  delete
        cwd  cdup  restart  rmdir  mkdir  alloc
        nlst  list  retr  stor  stou  appe  port
        pasv_xfer  pasv_xfer_unique  pasv_wait  abort  quit
    );

my %Undef_On_Fail_Commands = map { $_ => 1 }
    qw( site  pwd  get  put  put_unique  append  unique_name
        mdtm  size  pasv  quot
    );

my %In_List_Context_Commands = map { $_ => 1 }
    qw( ls  dir  feature);
    # feature will return empty list if feature is not supported

my %In_Scalar_Context_No_Fail_Commands = map { $_ => 1 }
    qw(supported  hash);

sub _methods_define {
    return ( process => '_wheel_entry', );
}

sub process {
    $poe_kernel->post( shift->{session_id} => process => @_ );
}

sub _check_args {
    my ( $self, $in_ref ) = @_;
    exists $in_ref->{commands}
        or carp "Missing `commands` argument"
        and return;

    return 1;
}

sub _prepare_wheel {
    my $self = shift;
    $self->{stop_on_error} = 1
        unless exists $self->{stop_on_error};
}

sub _process_request {
    my ( $self, $in_ref ) = @_;

    my @responses;
    my ( $is_error, $last_error );
    for ( @{ $in_ref->{commands} } ) {
        last
            if $self->{stop_on_error} and $is_error;

        my ( $command, $options_ref ) = %$_;
        $command = lc $command;
        eval {
            if ( $command eq 'new' ) {
                $self->{obj} = Net::FTP->new( @$options_ref )
                    or push @responses, [ $@ ]
                    and $is_error = $command
                    and $last_error = $@
                    and next;
                push @responses, [ 1 ];
            }
            elsif ( exists $True_False_Commands{ $command } ) {
                if ( my $res = $self->{obj}->$command( @$options_ref ) ) {
                    push @responses, [ $res ];
                }
                else {
                    my $error = $self->{obj}->message;
                    push @responses, [ $error ];
                    $is_error = $command;
                    $last_error = $error;
                }
            }
            elsif ( exists $Undef_On_Fail_Commands{ $command } ) {
                if ( defined(
                        my $res = $self->{obj}->$command( @$options_ref )
                ) ) {
                    push @responses, [ $res ];
                }
                else {
                    my $error = $self->{obj}->message;
                    push @responses, [ $error ];
                    $is_error = $command;
                }
            }
            elsif ( exists $In_List_Context_Commands{ $command } ) {
                push @responses,
                    [ $self->{obj}->$command( @$options_ref ) ];
            }
            elsif ( exists $In_Scalar_Context_No_Fail_Commands{ $command } ) {
                push @responses,
                    [ scalar $self->{obj}->$command( @$options_ref ) ];
            }
            else {
                croak "Invalid command `$command` was specified";
            }
        };
        if ( $@ ) { carp "Fatal error occured during execution: $@\n"; }
    }

    $in_ref->{is_error} = $is_error
        if $is_error;

    $in_ref->{last_error} = $last_error
        if $last_error;

    $in_ref->{responses} = \@responses;
}

1;
__END__