File Coverage

blib/lib/POE/Component/IRC/Plugin/WWW/Vim/Tips.pm

Criterion	Covered	Total	%
statement	20	43	46.5
branch	0	6	0.0
condition			n/a
subroutine	7	11	63.6
pod	0	4	0.0
total	27	64	42.1

package POE::Component::IRC::Plugin::WWW::Vim::Tips;

use 5.008_005;
use strict;
use warnings;

our $VERSION = '0.14';

use POE::Component::IRC::Plugin qw( :ALL );
use HTML::TreeBuilder::XPath;
use LWP::Simple qw(get);

sub new {
    my $package = shift;
    return bless {}, $package;
}

sub PCI_register {
    my ($self, $irc) = splice @_, 0, 2;

    $irc->plugin_register($self, 'SERVER', qw(public));
    return 1;
}

# This is method is mandatory but we don't actually have anything to do.
sub PCI_unregister {
    return 1;
}

sub S_public {
    my ($self, $irc) = splice @_, 0, 2;

    # Parameters are passed as scalar-refs including arrayrefs.
    my $nick    = (split /!/, ${$_[0]})[0];
    my $channel = ${$_[1]}->[0];
    my $msg     = ${$_[2]};

    my $reply =
        ($msg =~ /^!vimtips?\b/i)   ? $self->_get_vim_tip
      : ($msg =~ /^!emacstips?\b/i) ? 'use Vim'
      :                               '';
    if ($reply) {
        $irc->yield(privmsg => $channel => "$nick: $reply");
        return PCI_EAT_PLUGIN;
    }

    # Default action is to allow other plugins to process it.
    return PCI_EAT_NONE;
}

sub _get_vim_tip {
    my $content = get('http://twitter.com/vimtips');
    my $tree    = HTML::TreeBuilder::XPath->new_from_content($content);
    my @tips    = grep { s/\x{a0}/ /g; s/^\s*|\s*$//g; 1 }                #
      $tree->findvalues(
        './/div[@class=~/\bprofile-stream\b/]
          //p[@class=~/\btweet-text\b/]'
      );
    return $tips[rand @tips];
}

1;

__END__