File Coverage

blib/lib/OpenSSL/Versions.pm

Criterion	Covered	Total	%
statement	51	57	89.4
branch	21	28	75.0
condition			n/a
subroutine	10	11	90.9
pod	1	1	100.0
total	83	97	85.5

package OpenSSL::Versions;

use 5.006;
use strict;
use warnings;
use Carp;
use Exporter qw( import );

our $VERSION = '0.002';
$VERSION = eval $VERSION;

our @EXPORT = ();
our @EXPORT_OK = qw( parse_openssl_version_number );

sub parse_openssl_version_number {
    my ($vstr) = @_;

    $vstr =~ s/^0x//; # remove hex prefix

    # 0.9.6 or later : MNNFFPPS : major, minor, fix, patch, status (0-f)
    # 0.9.5a to before 0.9.6 : high bit of PP is set in MNNFFPPS
    # 0.9.3-dev to before 0.9.5a : MNNFFRBB : major, minor, fix, status (0-1), beta
    # prior to 0.9.3-dev, MNFP

    my @ret;

    if ( $vstr =~ /^(?:[1-9]|0090[6-9])/ ) {
        @ret = ( OpenSSL => _parse_openssl_v096_or_later( $vstr ) );
    }
    elsif ( $vstr =~ /^00905[8-9]/ ) {
        @ret = ( OpenSSL => _parse_openssl_v095a_096( $vstr ) );
    }
    elsif ( $vstr =~ /^0090[3-5][01]/ ) {
       @ret = ( OpenSSL => _parse_openssl_v093dev_095a( $vstr ) );
    }
    else {
        @ret = ( SSLeay => _parse_openssl_pre_v093dev( $vstr ) );
    }

    return wantarray ? reverse @ret : $ret[1];
}

sub _parse_openssl_v096_or_later {
    my ($vstr) = @_;

    # 0.9.6 or later : MNNFFPPS : major, minor, fix, patch, status (0-f)
    my $pat = join '', map "([[:xdigit:]]{$_})", (1, 2, 2, 2, 1);

    my @v = $vstr =~ /^$pat\z/;

    unless (@v == 5) {
        _croak_invalid_vstr($vstr);
    }

    # The value of OPENSSL_VERSION_NUMBER for in crypto/opensslv.h in the
    # OpenSSL 0.9.8f distribution is inconsistent with the description. We have
    # #define OPENSSL_VERSION_NUMBER	0x00908070L in the header file.
    # However, the comment above the definition states: "The status nibble has
    # one of the values 0 for development, 1 to e for betas 1 to 14, and f for
    # release." According to that description, the version string for that
    # number should be 0.9.8f-dev. This number is special cased below due to
    # that discrepancy.

    if ($vstr eq '00908070') {
        return '0.9.8f';
    }

    my ($major, $minor, $fix, $patch, $status) = map hex, @v;

    $patch = $patch ? chr( ord('a') + $patch - 1 ) : '';

    if    ( $status ==  0 ) { $status = '-dev' }
    elsif ( $status == 15 ) { $status = '' }
    else                    { $status = "-beta$status" }
    return sprintf( '%u.%u.%u%s%s', $major, $minor, $fix, $patch, $status);
}

sub _parse_openssl_v095a_096 {
    my ($vstr) = @_;

    # 0.9.5a to before 0.9.6 :
    # high bit of PP is set in MNNFFPPS

    return _parse_openssl_v096_or_later(
        sprintf '%08x', hex($vstr) & 0xfffff7ff
    );
}

sub _parse_openssl_v093dev_095a {
    my ($vstr) = @_;

    # Prior to 0.9.5a beta1, a different scheme was used:
    # MMNNFFRBB for major minor fix final patch/beta)

    my @v = $vstr =~ /^(0)(09)(0[3-5])([0-1])(..)\z/;

    unless (@v == 5) {
        _croak_invalid_vstr($vstr);
    }

    my ($major, $minor, $fix, $status, $patch) = map hex, @v;

    $patch = $patch ? chr( ord('a') + $patch - 1 ) : '';
    $status = $status ? '' : '-dev';
    return sprintf( '%u.%u.%u%s%s', $major, $minor, $fix, $patch, $status );
}

sub _parse_openssl_pre_v093dev {
    my ($vstr) = @_;

    # prior to 0.9.3-dev,
    # MNFP : major, minor, fix, patch

    my @v = $vstr =~ /^(0)(9)([12])([0-9])$/;

    unless (@v == 4) {
        croak "'$vstr' does not look like a valid value for OPENSSL_VERSION_NUMBER";
    }

    my ($major, $minor, $fix, $patch) = map hex, @v;

    $patch = $patch ? chr( ord('a') + $patch - 1 ) : '';
    return sprintf( '%u.%u.%u%s', $major, $minor, $fix, $patch );
}

sub _croak_invalid_vstr {
    my ($vstr) = @_;

    croak "'$vstr' does not look like a valid value for OPENSSL_VERSION_NUMBER";
}

1;

__END__