File Coverage

blib/lib/OpenInteract2/Action/RSS.pm

Criterion	Covered	Total	%
statement	13	15	86.6
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	20	90.0

package OpenInteract2::Action::RSS;

# $Id: RSS.pm,v 1.2 2004/12/02 04:31:30 cwinters Exp $

use strict;
use base qw( OpenInteract2::Action );
use Digest::MD5              qw( md5_hex );
use File::Spec::Functions    qw( catfile );
use Log::Log4perl            qw( get_logger );
use OpenInteract2::Constants qw( :log );
use OpenInteract2::Context   qw( CTX );
use OpenInteract2::Exception qw( oi_error );
use URI;
use XML::Feed;

$OpenInteract2::Action::RSS::VERSION          = '0.10';

# Use this if the action does not define its own template
$OpenInteract2::Action::RSS::DEFAULT_TEMPLATE = 'rss_feed_default';

# Use this if the action does not define its own title or title_key
$OpenInteract2::Action::RSS::DEFAULT_TITLE    = 'Feed';

my ( $log );

# always run the 'process' task

sub _find_task {
    return 'process';
}

# NOTE: we don't need to bother with caching the output content here
# -- execute() in the parent class takes care of it for us

sub process {
    my ( $self ) = @_;
    $log ||= get_logger( LOG_ACTION );

    my ( $url, $template, $feed );
    eval {
        $url = $self->_get_feed_url();
        $log->is_debug &&
            $log->debug( "Will load from feed URL '$url'" );
        $feed = $self->_load_feed( $url );
        $template = $self->_get_template_name();
        $log->is_debug &&
            $log->debug( "Will send feed and data to template '$template'" );
    };
    return "$@"  if ( $@ );
    $log->is_info && $log->info( "Got all necessary data, processing feed..." );
    my $title = $self->_get_title( $feed ) || $feed->title;
    my %params = (
        feed  => $feed,
        title => $title,
    );
    $self->_modify_template_params( \%params );
    return $self->generate_content( \%params, { name => $template } );
}


sub _get_feed_url {
    my ( $self ) = @_;
    my $class = ref( $self );
    my $url = $self->param( 'feed_url' );
    unless ( $url ) {
        $log->error( "No 'feed_url' defined for action ", $self->name );
        die "Cannot get feed: parameter 'feed_url' must be defined " .
            "for action '", $self->name, "'. (See $class for details).\n";
    }
    return $url;
}


sub _load_feed {
    my ( $self, $url ) = @_;
    my ( $feed );
    if ( $url =~ m|^file://| ) {
        my $file = $url;
        $file =~ s|^file://||;
        $log->is_info && $log->info( "Loading feed from file '$file'" );
        $feed = XML::Feed->parse( $file );
    }
    else {
        $log->is_info && $log->info( "Loading feed from URL '$url'" );
        $feed = XML::Feed->parse( URI->new( $url ) )
    }
    unless ( $feed ) {
        my $error = XML::Feed->errstr();
        $log->error( "Failed to load feed: ",  );
        die "Failed to load feed from '$url': $error\n";
    }
    return $feed;
}


sub _get_template_name {
    my ( $self ) = @_;
    my $template = $self->param( 'template' );
    if ( $template ) {
        $log->is_debug &&
            $log->debug( "Found template '$template' in action params" );
    }
    else {
        $log->is_debug &&
            $log->debug( "No RSS template configured, using default" );
        $template = $OpenInteract2::Action::RSS::DEFAULT_TEMPLATE;
        my $full_template_path =
            catfile( CTX->lookup_directory( 'template' ), $template );
        unless ( -f $full_template_path ) {
            $log->is_debug &&
                $log->debug( "Default template file does not exist, ",
                             "writing for the first time" );
            open( DEFAULT, '>', $full_template_path )
                || oi_error "Cannot create default RSS template at ",
                            "'$full_template_path': $!";
            print DEFAULT _get_default_template_content();
            close( DEFAULT );
            $log->is_debug &&
                $log->debug( "Wrote default RSS template ok" );
        }
    }
    return $template;
}


sub _get_default_template_content {
    return <<'CONTENT';
[%- rss_display_cap = OI.action_param( 'num_display' ) || feed.entries.size;
    count = 0; -%]
[% title %]
[% FOREACH entry = feed.entries;
       IF count < rss_display_cap; -%]
 - [% OI.date_format( entry.issued, '%b %d, %r' ) %]:
   [% entry.title %]
[%     END;
       count = count + 1;
   END -%]
CONTENT
}

sub _get_title {
    my ( $self, $feed ) = @_;
    my $title = $self->param( 'title' );
    unless ( $title ) {
        my $title_key = $self->param( 'title_key' );
        if ( $title_key ) {
            $title = CTX->request->language_handle->maketext( $title_key );
        }
    }
    return $title;
}

# For overriding...
sub _modify_template_params {}

1;

__END__