File Coverage

blib/lib/OpenAPI/Generator/From/Definitions.pm

Criterion	Covered	Total	%
statement	49	53	92.4
branch	13	22	59.0
condition	1	3	33.3
subroutine	11	11	100.0
pod	2	2	100.0
total	76	91	83.5

package OpenAPI::Generator::From::Definitions;

use strict;
use warnings;

use Carp qw(croak);
use File::Find;
use OpenAPI::Generator::Util qw(merge_definitions);

BEGIN {

  if (eval { require YAML::XS }) {
    YAML::XS->import('Load');
  }
  elsif (eval { require YAML }) {
    YAML->import('Load');
  }
  else {
    require CPAN::Meta::YAML;
    CPAN::Meta::YAML->import('Load');
  }

  if (eval { require JSON::XS }) {
    JSON::XS->import('decode_json')
  }
  else {
    require JSON::PP;
    JSON::PP->import('decode_json');
  }

}

sub new {

  bless {}, shift
}

sub generate {

  my($self, $conf) = @_;

  my $src = $conf->{src};
  $self->_check_src($src);
  my @files = $self->_src_as_files($src);

  if (!@files) {
    croak "no files found in $src";
  }

  my @defs = @{ $conf->{definitions} };

  for my $file (@files) {
    croak "$file is not readable" unless -r $file;

    local $/ = '';
    open my $fh, '<', $file or croak "can't open file $file";
    my $content = <$fh>;
    close $fh;


    if ($file =~ /\.json$/) {
      push @defs, decode_json($content);
    }
    else {
      push @defs, Load($content);
    }
  }

  merge_definitions(@defs)
}

sub _check_src {

  croak "$_[1] is not file or directory" unless(-f $_[1] or -d $_[1]);
  croak "$_[1] is not readable" unless(-r $_[1]);
}

sub _src_as_files {

  return $_[1] if -f $_[1];

  my @files;
  find sub { push @files, $File::Find::name if /\.(yml|yaml|json)$/ }, $_[1];
  @files
}

1

__END__