File Coverage

blib/lib/Object/Signature/Portable.pm

Criterion	Covered	Total	%
statement	35	37	94.5
branch	6	8	75.0
condition	5	6	83.3
subroutine	9	9	100.0
pod	1	1	100.0
total	56	61	91.8

package Object::Signature::Portable;

# ABSTRACT: generate portable fingerprints of objects

use v5.10;

use strict;
use warnings;

use Carp;
use Crypt::Digest;
use Exporter 5.57 qw/ import /;
use JSON::MaybeXS;

our $VERSION = 'v1.1.2';

our @EXPORT    = qw/ signature /;
our @EXPORT_OK = @EXPORT;


sub signature {
    my %args;

    if ( scalar(@_) <= 1 ) {
        $args{data} = $_[0];
    } else {
        %args = @_;
    }

    $args{digest} //= 'MD5';

    $args{format} //= 'hexdigest';
    unless ( $args{format} =~ m/^(?:hex|b64u?)digest$/ ) {
        croak sprintf( 'Invalid digest format: %s', $args{format} );
    }

    $args{serializer} //= sub {
        return JSON->new->canonical(1)->allow_nonref(1)->utf8(1)->pretty(0)
            ->indent(0)->space_before(0)->space_after(0)->allow_blessed(1)
            ->convert_blessed(1)->encode( $_[0] );
    };

    my $digest = Crypt::Digest->new( $args{digest} );
    $digest->add( &{ $args{serializer} }( $args{data} ) );

    if ( my $method = $digest->can( $args{format} ) ) {
        my $prefix = $args{prefix} ? ( $args{digest} . ':' ) : '';
        return $prefix . $digest->$method;
    } else {
        croak sprintf( 'Unexpected error with digest format: %s',
            $args{format} );
    }
}


1;

__END__