File Coverage

blib/lib/Object/FromData/Array.pm

Criterion	Covered	Total	%
statement	26	33	78.7
branch	4	6	66.6
condition			n/a
subroutine	7	11	63.6
pod	8	8	100.0
total	45	58	77.5

package Object::FromData::Array;

use strict;
use warnings;

sub _new {
    my ( $class, $arg_for ) = @_;

    my $arrayref = $arg_for->{ref};
    my @array;
    my $self = {
        array         => \@array,
        current_index => 0,
    };
    foreach my $item (@$arrayref) {
        if ( 'ARRAY' eq ref $item ) {
            push @array => $class->_new( { ref => $item } );
        }
        elsif ( 'HASH' eq ref $item ) {
            push @array => Object::FromData::Hash->_new( { ref => $item } );
        }
        else {
            push @array => $item;    # accept it raw
        }
    }
    return bless $self => $class;
}

sub current_index {
    my $self = shift;
    return $self->{current_index};
}

sub num_elems {
    my $self = shift;
    return scalar @{ $self->{array} };
}

sub reset {
    my $self = shift;
    $self->{current_index} = 0;
}

sub all {
    my $self = shift;
    return @{ $self->{array} };
}

sub has_more {
    my $self     = shift;
    my $arrayref = $self->{array};
    return $self->{current_index} <= $#$arrayref;
}

sub next {
    my $self = shift;
    return unless $self->has_more;
    return $self->{array}->[ $self->{current_index}++ ];
}

sub is_hashref  { }
sub is_arrayref {1}

1;

__END__