File Coverage

blib/lib/Object/Anon.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	6	6	100.0
condition	2	2	100.0
subroutine	13	13	100.0
pod	0	1	0.0
total	67	68	98.5

package Object::Anon;
$Object::Anon::VERSION = '0.002';
# ABSTRACT: Create objects on the fly

use strict;
use warnings;

use Carp qw(croak);

use Exporter qw(import);
our @EXPORT = qw(anon);

sub anon (%) {
    my ($hash) = @_;
    return _objectify($hash);
}

use overload ();
my %overload_ops = map { $_ => 1 } map { split /\s+/, $_ } values %overload::ops;

my $anon_class_id = 0;

sub _objectify {
    my ($hash, $seen) = @_;
    $seen ||= {};

    if ($seen->{$hash}) {
        croak "circular reference detected";
    }
    $seen->{$hash} = 1;

    my $class = "Object::Anon::__ANON__::".$anon_class_id++;

    for my $key (keys %$hash) {
        if ($overload_ops{$key}) {
            $class->overload::OVERLOAD($key => _value_sub($hash->{$key}, $seen));
        }
        else {
            no strict 'refs';
            *{$class."::".$key} = _value_sub($hash->{$key}, $seen);
        }
    }

    return bless do { \my %o }, $class;
}

sub _value_sub {
    my ($value, $seen) = @_;

    do {
        {
            HASH  => sub { my $o = _objectify($value, $seen); sub { $o } },
            ARRAY => sub { my @o = map { _value_sub($_, $seen)->() } @$value; sub { \@o } },
            CODE  => sub { $value },
        }->{ref $value} || sub { sub { $value } }
    }->();
}

1;
__END__