File Coverage

blib/lib/OPM/Repository.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	15	22	68.1
condition			n/a
subroutine	11	11	100.0
pod	3	3	100.0
total	88	95	92.6

package OPM::Repository;

# ABSTRACT: parse OPM repositories' framework.xml files to search for add ons

use strict;
use warnings;

our $VERSION = '1.0.0'; # VERSION

use Moo;
use List::Util qw(all);
use Scalar::Util qw(blessed);
use Regexp::Common qw(URI);

use OPM::Repository::Source;

our $ALLOWED_SCHEME = [ 'HTTP', 'file' ];

has sources => ( is => 'ro', required => 1, isa => sub {
    die "no valid URIs" unless
        ref $_[0] eq 'ARRAY'
        and
        all { _check_uri( $_ ) } @{ $_[0] }
});

has _objects => ( is => 'ro', isa => sub {
    die "no valid objects" unless
        ref $_[0] eq 'ARRAY'
        and
        all { blessed $_ and $_->isa( 'OPM::Repository::Source' ) } @{ $_[0] }
});

sub find {
    my ($self, %params) = @_;

    my @found;
    for my $source ( @{ $self->_objects || [] } ) {
        my $found = $source->find( %params );
        push @found, $found if $found;
    }

    return @found;
}

sub list {
    my ($self, %params) = @_;

    my %found_packages;
    my @detailed_list;
    for my $source ( @{ $self->_objects || [] } ) {
        my @found = $source->list( %params );
        @found_packages{@found} = (1) x @found;
        push @detailed_list, @found;
    }

    my @packages;
    if ( $params{details} ) {
        @packages = sort { $a->{name} cmp $b->{name} || $a->{version} cmp $b->{version} }@detailed_list;
    }
    else {
        @packages = sort keys %found_packages;
    }

    return @packages;
}

sub BUILDARGS {
    my ($class, @args) = @_;

    unshift @args, 'sources' if @args % 2;

    my %param = @args;

    for my $url ( @{ $param{sources} || [] } ) {
        push @{ $param{_objects} }, OPM::Repository::Source->new( url => $url );
    }

    return \%param;
}

sub _check_uri {
    my @allowed_schemes = ref $ALLOWED_SCHEME ? @{ $ALLOWED_SCHEME } : $ALLOWED_SCHEME;

    my $matches;

    SCHEME:
    for my $scheme ( @allowed_schemes ) {
        my $regex = ( lc $scheme eq 'http' ) ?
            $RE{URI}{HTTP}{-scheme => qr/https?/} :
            $RE{URI}{$scheme};

        if ( $_[0] =~ m{\A$regex\z} ) {
            $matches++;
            last SCHEME;
        }
    }

    die "No valid URI" unless $matches;
    return 1;
}

1;

__END__