File Coverage

blib/lib/OAuth/Lite2/Server/GrantHandler/AuthorizationCode.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	15	20	75.0
condition	4	9	44.4
subroutine	6	6	100.0
pod	1	1	100.0
total	57	67	85.0

package OAuth::Lite2::Server::GrantHandler::AuthorizationCode;

use strict;
use warnings;

use parent 'OAuth::Lite2::Server::GrantHandler';
use OAuth::Lite2::Server::Error;
use Carp ();

sub handle_request {
    my ($self, $dh) = @_;

    my $req = $dh->request;

    my $client_id = $req->param("client_id");

    my $code = $req->param("code")
        or OAuth::Lite2::Server::Error::InvalidRequest->throw(
            description => "'code' not found"
        );

    my $redirect_uri = $req->param("redirect_uri")
        or OAuth::Lite2::Server::Error::InvalidRequest->throw(
            description => "'redirect_uri' not found"
        );

    my $auth_info = $dh->get_auth_info_by_code($code)
        or OAuth::Lite2::Server::Error::InvalidGrant->throw;

    Carp::croak "OAuth::Lite2::Server::DataHandler::get_auth_info_by_code doesn't return OAuth::Lite2::Model::AuthInfo"
        unless ($auth_info
            && $auth_info->isa("OAuth::Lite2::Model::AuthInfo"));

    OAuth::Lite2::Server::Error::InvalidClient->throw
        unless ($auth_info->client_id eq $client_id);

    OAuth::Lite2::Server::Error::RedirectURIMismatch->throw
        unless ( $auth_info->redirect_uri
            && $auth_info->redirect_uri eq $redirect_uri);

    my $access_token = $dh->create_or_update_access_token(
        auth_info => $auth_info,
    );
    Carp::croak "OAuth::Lite2::Server::DataHandler::create_or_update_access_token doesn't return OAuth::Lite2::Model::AccessToken"
        unless ($access_token
            && $access_token->isa("OAuth::Lite2::Model::AccessToken"));

    my $res = {
        token_type => 'Bearer',
        access_token => $access_token->token,
    };

    $res->{expires_in} = $access_token->expires_in
        if $access_token->expires_in;
    $res->{refresh_token} = $auth_info->refresh_token
        if $auth_info->refresh_token;
    $res->{scope} = $auth_info->scope
        if $auth_info->scope;

    return $res;
}

=head1 NAME

OAuth::Lite2::Server::GrantHandler::AuthorizationCode - handler for 'authorization-code' grant_type request

=head1 SYNOPSIS

    my $handler = OAuth::Lite2::Server::GrantHandler::AuthorizationCode->new;
    my $res = $handler->handle_request( $data_handler );

=head1 DESCRIPTION

handler for 'authorization-code' grant_type request.

=head1 METHODS

=head2 handle_request( $req )

See L document.

=head1 AUTHOR

Lyo Kato, [e-mail]

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2010 by Lyo Kato

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.8.8 or,
at your option, any later version of Perl 5 you may have available.

=cut

1;