File Coverage

blib/lib/Number/Pad.pm

Criterion	Covered	Total	%
statement	47	54	87.0
branch	11	14	78.5
condition	1	2	50.0
subroutine	7	7	100.0
pod	1	1	100.0
total	67	78	85.9

package Number::Pad;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2021-08-01'; # DATE
our $DIST = 'Number-Pad'; # DIST
our $VERSION = '0.001'; # VERSION

use 5.010001;
use strict;
use warnings;

use List::Util qw(max);

use Exporter;
our @ISA = qw(Exporter);
our @EXPORT_OK = qw(
                       pad_numbers
               );

sub pad_numbers {
    # note: the same logic of this function is also in
    # Perinci::Result::Format::Lite. perhaps in the future that module will be
    # refactored to use us.

    # XXX we just want to turn off 'uninitialized' and 'negative repeat
    # count does nothing' from the operator x
    no warnings;

    require String::Pad;

    my ($numbers, $width, $which, $padchar, $truncate) = @_;

    $which //= 'l';

    # determine max widths
    my ($maxw_bd, $maxw_d, $maxw_ad); # before digit, digit, after d

    my (@w_bd, @w_d, @w_ad);
    for my $i (0..$#{$numbers}) {
        my $number = $numbers->[$i];
        my $width = length($number);
        if (!defined $number) {
            push @w_bd, 0;
            push @w_bd, 0;
            push @w_ad, 0;
        } elsif ($number =~ /\A([+-]?\d+)(\.?)(\d*)[%]?\z/) {
            # decimal notation number (with optional percent sign). TODO: allow
            # arbitraty units after number, e.g. ml, mcg, etc? but should we
            # align the unit too?
            push @w_bd, length($1);
            push @w_d , length($2);
            push @w_ad, length($3);
        } elsif ($number =~ /\A([+-]?\d+\.?\d*)([eE])([+-]?\d+)\z/) {
            # scientific notation number
            push @w_bd, length($1);
            push @w_d , length($2);
            push @w_ad, length($3);
        } elsif ($number =~ /\A([+-]?(?:Inf|NaN))\z/i) {
            push @w_bd, length($1);
            push @w_d , 1;
            push @w_ad, 0;
        } else {
            # not a number
            push @w_bd, length($number);
            push @w_bd, 0;
            push @w_ad, 0;
        }
    }
    my $maxw_bd = max(@w_bd);
    my $maxw_d  = max(@w_d);
    my $maxw_ad = max(@w_ad);

    # align the decimal point/"E" in the numbers first
    my @aligned_numbers;
    for my $number (@$numbers) {
        my ($bd, $d, $ad);
        if (($bd, $d, $ad) = $number =~ /\A([+-]?\d+)(\.?)(\d*)\z/) {
            push @aligned_numbers, join(
                '',
                (' ' x ($maxw_bd - length($bd))), $bd,
                $d , (' ' x ($maxw_d  - length($d ))),
                $ad, (' ' x ($maxw_ad - length($ad))),
            );
        } elsif (($bd, $d, $ad) = $number =~ /\A([+-]?\d+\.?\d*)([eE])([+-]?\d+)\z/) {
            push @aligned_numbers, join(
                '',
                (' ' x ($maxw_bd - length($bd))), $bd,
                $d , (' ' x ($maxw_d  - length($d ))),
                $ad, (' ' x ($maxw_ad - length($ad))),
            );
        } elsif (($bd, undef, undef) = $number =~ /\A([+-]?(?:Inf|NaN))\z/i) {
            push @aligned_numbers, join(
                '',
                (' ' x ($maxw_bd - length($bd))), $bd,
                '' , (' ' x ($maxw_d  - length($d ))),
                '', (' ' x ($maxw_ad - length($ad))),
            );
        } else {
            # not a number
            push @aligned_numbers, $number;
        }
    }

    # then pad with String::Pad
    String::Pad::pad(
        \@aligned_numbers,
        $width,
        $which,
        $padchar,
        $truncate,
    );
}

1;
# ABSTRACT: Pad numbers so the decimal point (or "E" if in exponential notation) align

__END__