File Coverage

blib/lib/Net/SecurityCenter/API/Report.pm

Criterion	Covered	Total	%
statement	32	46	69.5
branch	5	18	27.7
condition			n/a
subroutine	7	8	87.5
pod	3	3	100.0
total	47	75	62.6

package Net::SecurityCenter::API::Report;

use warnings;
use strict;

use Carp;

use parent 'Net::SecurityCenter::Base';

use Net::SecurityCenter::Utils qw(:all);

our $VERSION = '0.311';

my $common_template = {

    id => {
        required => 1,
        allow    => qr/^\d+$/,
        messages => {
            required => 'Report ID is required',
            allow    => 'Invalid Report ID',
        },
    },

    filter => {
        allow => [ 'running', 'completed', 'usable', 'manageable' ],
    },

    fields => {
        filter => \&sc_filter_array_to_string,
    }

};

#-------------------------------------------------------------------------------
# METHODS
#-------------------------------------------------------------------------------

sub list {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        filter => $common_template->{'filter'},
        raw    => {},
    };

    my $params  = sc_check_params( $tmpl, \%args );
    my $raw     = delete( $params->{'raw'} );
    my $reports = $self->client->get( '/report', $params );

    return if ( !$reports );

    if ($raw) {
        return wantarray ? @{$reports} : $reports;
    }

    return wantarray ? @{ sc_merge($reports) } : sc_merge($reports);

}

#-------------------------------------------------------------------------------

sub get {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        id     => $common_template->{'id'},
        raw    => {},
    };

    my $params = sc_check_params( $tmpl, \%args );

    my $report_id = delete( $params->{'id'} );
    my $raw       = delete( $params->{'raw'} );

    my $report = $self->client->get( "/report/$report_id", $params );

    return         if ( !$report );
    return $report if ($raw);
    return sc_normalize_hash($report);

}

#-------------------------------------------------------------------------------

sub download {

    my ( $self, %args ) = @_;

    my $tmpl = {
        filename => {},
        id       => $common_template->{'id'},
    };

    my $params = sc_check_params( $tmpl, \%args );

    my $report_id = delete( $params->{'id'} );
    my $filename  = delete( $params->{'filename'} );

    my $report_data = $self->client->post("/report/$report_id/download");

    return $report_data if ( !$filename );

    open my $fh, '>', $filename
        or croak("Could not open file '$filename': $!");

    print $fh $report_data;

    close $fh
        or carp("Failed to close file '$filename': $!");

    return 1;

}

#-------------------------------------------------------------------------------

1;

__END__