File Coverage

blib/lib/Net/SecurityCenter/API/Policy.pm

Criterion	Covered	Total	%
statement	42	69	60.8
branch	5	18	27.7
condition			n/a
subroutine	9	12	75.0
pod	7	7	100.0
total	63	106	59.4

package Net::SecurityCenter::API::Policy;

use warnings;
use strict;

use Carp;

use parent 'Net::SecurityCenter::Base';

use Net::SecurityCenter::Utils qw(:all);

our $VERSION = '0.311';

my $single_id_filter = sub {
    return { 'id' => $_[0] };
};

my $common_template = {

    id => {
        required => 1,
        allow    => qr/^\d+$/,
        messages => {
            required => 'Policy ID is required',
            allow    => 'Invalid Policy ID',
        },
    },

    policy_template => {
        remap    => 'policyTemplate',
        required => 1,
        filter   => \&$single_id_filter
    },

    name        => {},
    description => {},
    tags        => {},

    filter => {
        allow => [ 'usable', 'manageable' ],
    },

    fields => {
        filter => \&sc_filter_array_to_string,
    },

};

#-------------------------------------------------------------------------------
# METHODS
#-------------------------------------------------------------------------------

sub list {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        filter => $common_template->{'filter'},
        raw    => {}
    };

    my $params   = sc_check_params( $tmpl, \%args );
    my $raw      = delete( $params->{'raw'} );
    my $policies = $self->client->get( '/policy', $params );

    return if ( !$policies );

    if ($raw) {
        return wantarray ? @{$policies} : $policies;
    }

    return wantarray ? @{ sc_merge($policies) } : sc_merge($policies);

}

#-------------------------------------------------------------------------------

sub get {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        id     => $common_template->{'id'},
        raw    => {},
    };

    my $params    = sc_check_params( $tmpl, \%args );
    my $policy_id = delete( $params->{'id'} );
    my $raw       = delete( $params->{'raw'} );
    my $policy    = $self->client->get( "/policy/$policy_id", $params );

    return         if ( !$policy );
    return $policy if ($raw);
    return sc_normalize_hash($policy);

}

#-------------------------------------------------------------------------------

sub create {

    my ( $self, %args ) = @_;

    my $tmpl = {
        name => {
            required => 1,
        },
        description     => {},
        policy_template => $common_template->{'policy_template'},
        tags            => {},
        preferences     => {},
        families        => {},
    };

    my $params = sc_check_params( $tmpl, \%args );
    my $policy = $self->client->post( '/policy', $params );

    return sc_normalize_hash($policy);

}

#-------------------------------------------------------------------------------

sub edit {

    my ( $self, %args ) = @_;

    my $tmpl = {
        id           => $common_template->{'id'},
        name         => {},
        description  => {},
        tags         => {},
        preferences  => {},
        families     => {},
        remove_prefs => {
            remap => 'removePrefs'
        }
    };

    my $params    = sc_check_params( $tmpl, \%args );
    my $policy_id = delete( $params->{'id'} );
    my $policy    = $self->client->patch( "/policy/$policy_id", $params );

    return sc_normalize_hash($policy);

}

#-------------------------------------------------------------------------------

sub copy {

    my ( $self, %args ) = @_;

    my $tmpl = {
        id   => $common_template->{'id'},
        name => {},
    };

    my $params    = sc_check_params( $tmpl, \%args );
    my $policy_id = delete( $params->{'id'} );
    my $policy    = $self->client->post( "/policy/$policy_id/copy", $params );

    return sc_normalize_hash($policy);

}

#-------------------------------------------------------------------------------

sub delete {

    my ( $self, %args ) = @_;

    my $tmpl = { id => $common_template->{'id'} };

    my $params    = sc_check_params( $tmpl, \%args );
    my $policy_id = delete( $params->{'id'} );

    $self->client->delete("/policy/$policy_id");

    return 1;

}

#-------------------------------------------------------------------------------

sub download {

    my ( $self, %args ) = @_;

    my $tmpl = {
        filename => {},
        id       => $common_template->{'id'},
    };

    my $params = sc_check_params( $tmpl, \%args );

    my $policy_id = delete( $params->{'id'} );
    my $filename  = delete( $params->{'filename'} );

    my $policy_data = $self->client->post("/policy/$policy_id/export");

    return $policy_data if ( !$filename );

    open my $fh, '>', $filename
        or croak("Could not open file '$filename': $!");

    print $fh $policy_data;

    close $fh
        or carp("Failed to close file '$filename': $!");

    return 1;

}

#-------------------------------------------------------------------------------

1;

__END__