File Coverage

blib/lib/Net/SecurityCenter/API/Plugin.pm

Criterion	Covered	Total	%
statement	39	64	60.9
branch	6	22	27.2
condition			n/a
subroutine	9	11	81.8
pod	3	3	100.0
total	57	100	57.0

package Net::SecurityCenter::API::Plugin;

use warnings;
use strict;

use Carp;
use MIME::Base64;
use Params::Check qw(allow);

use parent 'Net::SecurityCenter::Base';

use Net::SecurityCenter::Utils qw(:all);

our $VERSION = '0.311';

my $common_template = {

    id => {
        required => 1,
        allow    => qr/^\d+$/,
        messages => {
            required => 'Plugin ID is required',
            allow    => 'Invalid Plugin ID',
        },
    },

    filter => {
        allow => [ 'usable', 'manageable' ],
    },

    fields => {
        filter => \&sc_filter_array_to_string,
    },

};

#-------------------------------------------------------------------------------
# METHODS
#-------------------------------------------------------------------------------

sub list {

    my ( $self, %args ) = @_;

    my $tmpl = {
        raw    => {},
        fields => $common_template->{'fields'},
        type   => {
            allow => [ 'active', 'all', 'compliance', 'custom', 'lce', 'notPassive', 'passive' ],
        },
        sort_field => {
            allow => [ 'modifiedTime', 'id', 'name', 'family', 'type' ],
            remap => 'sortDirection',
        },
        start_offset => {
            allow => qr/^\d+$/,
            remap => 'startOffset',
        },
        end_offset => {
            allow => qr/^\d+$/,
            remap => 'endOffset',
        },
        sort_direction => {
            allow  => [ 'ASC', 'DESC' ],
            remap  => 'sortDirection',
            filter => sub { uc $_[0] },
        },
        since => {
            allow => qr/^\d+$/,
        },
        filter_field => {
            allow => [
                'copyright',        'description',     'exploitAvailable', 'family',
                'id',               'name',            'patchPubDate',     'patchModDate',
                'pluginPubDate',    'pluginModDate',   'sourceFile',       'type',
                'version',          'vulnPubDate',     'xrefs',            'xrefs:ALAS',
                'xrefs:APPLE-SA',   'xrefs:AUSCERT',   'xrefs:BID',        'xrefs:CERT',
                'xrefs:CERT-CC',    'xrefs:CERT-FI',   'xrefs:CERTA',      'xrefs:CISCO-BUG-ID',
                'xrefs:CISCO-SA',   'xrefs:CISCO-SR',  'xrefs:CLSA',       'xrefs:CONECTIVA',
                'xrefs:CVE',        'xrefs:CWE',       'xrefs:DSA',        'xrefs:EDB-ID',
                'xrefs:FEDORA',     'xrefs:FLSA',      'xrefs:FreeBSD',    'xrefs:GLSA',
                'xrefs:HP',         'xrefs:HPSB',      'xrefs:IAVA',       'xrefs:IAVB',
                'xrefs:IAVT',       'xrefs:ICS-ALERT', 'xrefs:ICSA',       'xrefs:MDKSA',
                'xrefs:MDVSA',      'xrefs:MGASA',     'xrefs:MSFT',       'xrefs:MSVR',
                'xrefs:NSFOCUS',    'xrefs:NessusID',  'xrefs:OSVDB',      'xrefs:OWASP',
                'xrefs:OpenPKG-SA', 'xrefs:RHSA',      'xrefs:SSA',        'xrefs:Secunia',
                'xrefs:SuSE',       'xrefs:TLSA',      'xrefs:TSLSA',      'xrefs:USN',
                'xrefs:VMSA',       'xrefs:zone-h'
            ],
            remap => 'filterField',
        },
        op => {
            allow => [ 'eq', 'gt', 'gte', 'like', 'lt', 'lte' ]
        },
        value  => {},
        filter => {},
    };

    if ( defined( $args{'filter'} ) ) {

        if ( ref $args{'filter'} ne 'ARRAY' ) {
            carp "Filter is not ARRAY";
            croak 'Usage: ' . __PACKAGE__ . '->list ( filter => [ FIELD, OPERATOR, VALUE ], ... )';
        }

        my ( $filter_field, $operator, $value ) = @{ $args{'filter'} };

        $args{'filter_field'} = $filter_field;
        $args{'op'}           = $operator;
        $args{'value'}        = $value;

        delete( $args{'filter'} );

    }

    my $params  = sc_check_params( $tmpl, \%args );
    my $raw     = delete( $params->{'raw'} );
    my $plugins = $self->client->get( '/plugin', $params );

    return if ( !$plugins );

    if ($raw) {
        return wantarray ? @{$plugins} : $plugins;
    }

    return wantarray ? @{ sc_normalize_array($plugins) } : sc_normalize_array($plugins);

}

#-------------------------------------------------------------------------------

sub get {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        id     => $common_template->{'id'},
        raw    => {},
    };

    my $params    = sc_check_params( $tmpl, \%args );
    my $raw       = delete( $params->{'raw'} );
    my $plugin_id = delete( $params->{'id'} );
    my $plugin    = $self->client->get( "/plugin/$plugin_id", $params );

    return         if ( !$plugin );
    return $plugin if ($raw);

    return sc_normalize_hash($plugin);

}

#-------------------------------------------------------------------------------

sub download {

    my ( $self, %args ) = @_;

    my $tmpl = {
        filename => {},
        id       => $common_template->{'id'},
    };

    my $params    = sc_check_params( $tmpl, \%args );
    my $plugin_id = delete( $params->{'id'} );
    my $filename  = delete( $params->{'filename'} );

    my $plugin_data   = $self->client->get( "/plugin/$plugin_id", { 'fields' => 'id,source' } )->{'source'};
    my $plugin_source = decode_base64($plugin_data);

    return $plugin_source if ( !$filename );

    open my $fh, '>', $filename
        or croak("Could not open file '$filename': $!");

    print $fh $plugin_source;

    close $fh
        or carp("Failed to close file '$filename': $!");

    return 1;

}

#-------------------------------------------------------------------------------

1;

__END__