File Coverage

blib/lib/Net/SecurityCenter/API/Ticket.pm

Criterion	Covered	Total	%
statement	32	48	66.6
branch	5	14	35.7
condition			n/a
subroutine	7	9	77.7
pod	4	4	100.0
total	48	75	64.0

package Net::SecurityCenter::API::Ticket;

use warnings;
use strict;

use Carp;

use parent 'Net::SecurityCenter::Base';

use Net::SecurityCenter::Utils qw(:all);

our $VERSION = '0.310';

my $common_template = {

    id => {
        required => 1,
        allow    => qr/^\d+$/,
        messages => {
            required => 'Ticket ID is required',
            allow    => 'Invalid Ticket ID',
        },
    },

    fields => {
        filter => \&sc_filter_array_to_string,
    },

    assignee => {
        allow  => qr/\d+/,
        errors => { allow => 'Invalid Asignee ID' },
        filter => sub {
            return { 'id' => $_[0] };
        }
    },

    status => {
        allow => [ 'assigned', 'resolved', 'feedback', 'na', 'duplicate', 'closed' ]
    },

    classification => {
        allow => [
            'Information',
            'Configuration',
            'Patch',
            'Disable',
            'Firewall',
            'Schedule',
            'IDS',
            'Other',
            'Accept Risk',
            'Recast Risk',
            'Re-scan Request',
            'False Positive',
            'System Probe',
            'External Probe',
            'Investigation Needed',
            'Compromised System',
            'Virus Incident',
            'Bad Credentials',
            'Unauthorized Software',
            'Unauthorized System',
            'Unauthorized User'
        ]
    },

};

#-------------------------------------------------------------------------------
# METHODS
#-------------------------------------------------------------------------------

sub list {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        raw    => {},
    };

    my $params  = sc_check_params( $tmpl, \%args );
    my $raw     = delete( $params->{'raw'} );
    my $tickets = $self->client->get( '/ticket', $params );

    return if ( !$tickets );

    if ($raw) {
        return wantarray ? @{$tickets} : $tickets;
    }

    return wantarray ? @{ sc_merge($tickets) } : sc_merge($tickets);

}

#-------------------------------------------------------------------------------

sub get {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        id     => $common_template->{'id'},
        raw    => {},
    };

    my $params    = sc_check_params( $tmpl, \%args );
    my $raw       = delete( $params->{'raw'} );
    my $ticket_id = delete( $params->{'id'} );
    my $ticket    = $self->client->get( "/ticket/$ticket_id", $params );

    return         if ( !$ticket );
    return $ticket if ($raw);
    return sc_normalize_hash($ticket);

}

#-------------------------------------------------------------------------------

sub add {

    my ( $self, %args ) = @_;

    my $tmpl = {
        name => {
            required => 1,
            errors   => { required => 'Specify ticket name' }
        },
        assignee       => $common_template->{'asignee'},
        status         => $common_template->{'status'},
        classification => $common_template->{'classification'},
        description    => {},
        notes          => {},
        queries        => {},
        query          => {}
    };

    my $params = sc_check_params( $tmpl, \%args );

    my $result = $self->client->post( '/ticket', $params );

    return $result->{id};

}

#-------------------------------------------------------------------------------

sub edit {

    my ( $self, %args ) = @_;

    my $tmpl = {
        id             => $common_template->{'id'},
        name           => {},
        assignee       => $common_template->{'asignee'},
        status         => $common_template->{'status'},
        classification => $common_template->{'classification'},
        description    => {},
        notes          => {},
        queries        => {},
        query          => {},
        raw            => {}
    };

    my $params    = sc_check_params( $tmpl, \%args );
    my $ticket_id = delete( $params->{'id'} );
    my $raw       = delete( $params->{'raw'} );

    my $ticket = $self->client->patch( "/ticket/$ticket_id", $params );

    return $ticket if ($raw);
    return sc_normalize_hash($ticket);

}

1;

__END__