File Coverage

blib/lib/Net/SecurityCenter/API/System.pm

Criterion	Covered	Total	%
statement	53	73	72.6
branch	12	18	66.6
condition			n/a
subroutine	7	12	58.3
pod	8	8	100.0
total	80	111	72.0

package Net::SecurityCenter::API::System;

use warnings;
use strict;

use parent 'Net::SecurityCenter::Base';

use Net::SecurityCenter::Utils qw(:all);

our $VERSION = '0.310';

#-------------------------------------------------------------------------------
# METHODS
#-------------------------------------------------------------------------------

sub get_status {

    my ( $self, %args ) = @_;

    deprecated
        '"Net::SecurityCenter::API::System->get_status" is DEPRECATED use "Net::SecurityCenter::API::Status->status" instead';

    return;

}

#-------------------------------------------------------------------------------

sub get_info {

    my ( $self, %args ) = @_;

    deprecated
        '"Net::SecurityCenter::API::Status->get_info" is DEPRECATED use "Net::SecurityCenter::API::Status->info"';

    return $self->info( \%args );

}

#-------------------------------------------------------------------------------

sub info {

    my ( $self, %args ) = @_;

    my $tmpl = { raw => {}, };

    my $params = sc_check_params( $tmpl, \%args );
    my $raw    = delete( $params->{'raw'} );
    my $info   = $self->client->get('/system');

    return       if ( !$info );
    return $info if ($raw);

    return sc_normalize_hash($info);

}

#-------------------------------------------------------------------------------

sub debug {

    my ( $self, %args ) = @_;

    my $tmpl = { name => {}, id => {}, category => {} };

    my $params   = sc_check_params( $tmpl, \%args );
    my $id       = delete( $params->{'id'} );
    my $name     = delete( $params->{'name'} );
    my $category = delete( $params->{'category'} );
    my $debug    = $self->client->get('/system/debug');

    return if ( !$debug );

    my $id_results       = {};
    my $name_results     = {};
    my $category_results = {};

    foreach my $item ( @{$debug} ) {

        $id_results->{ $item->{id} }     = $item;
        $name_results->{ $item->{name} } = $item;

        if ( !defined( $category_results->{ $item->{category} } ) ) {
            $category_results->{ $item->{category} } = ();
        }

        push @{ $category_results->{ $item->{category} } }, $item;

    }

    if ($name) {
        return $name_results->{$name};
    }

    if ($id) {
        return $id_results->{$id};
    }

    if ($category) {
        return $category_results->{$category};
    }

    return $debug;

}

#-------------------------------------------------------------------------------

sub get_diagnostics_info {

    my ( $self, %args ) = @_;

    my $tmpl = { raw => {}, };

    my $params = sc_check_params( $tmpl, \%args );
    my $raw    = delete( $params->{'raw'} );
    my $info   = $self->client->get('/system/diagnostics');

    if ( !$info ) {
        return;
    }

    if ($raw) {
        return $info;
    }

    return sc_normalize_hash($info);

}

#-------------------------------------------------------------------------------

sub generate_diagnostics_app_status {

    my ($self) = @_;
    $self->client->post( '/system/diagnostics/generate', { 'task' => 'appStatus' } );
    return 1;

}

#-------------------------------------------------------------------------------

sub generate_diagnostics_file {

    my ( $self, %args ) = @_;

    my $tmpl = {
        type => {
            default => ['all'],
            allow   => [
                'all',        'apacheLog', 'configuration', 'dependencies', 'dirlist',    'environment',
                'installLog', 'logs',      'sanitize',      'scans',        'serverConf', 'setup',
                'sysinfo',    'upgradeLog'
            ]
        },
    };

    my $params  = sc_check_params( $tmpl, \%args );
    my $options = delete( $params->{'type'} );

    return $self->client->post( '/system/diagnostics/generate',
        { 'task' => 'diagnosticsFile', 'options' => \@{$options} } );

}

#-------------------------------------------------------------------------------

sub download_diagnostics {

    my ($self) = @_;
    return $self->client->post('/system/diagnostics/download');

}

#-------------------------------------------------------------------------------

1;

__END__