File Coverage

blib/lib/Net/SecurityCenter/API/Repository.pm

Criterion	Covered	Total	%
statement	32	49	65.3
branch	5	16	31.2
condition			n/a
subroutine	7	10	70.0
pod	4	4	100.0
total	48	79	60.7

package Net::SecurityCenter::API::Repository;

use warnings;
use strict;

use Carp;

use parent 'Net::SecurityCenter::Base';

use Net::SecurityCenter::Utils qw(:all);

our $VERSION = '0.310';

my $common_template = {

    id => {
        required => 1,
        allow    => qr/^\d+$/,
        messages => {
            required => 'Repository ID is required',
            allow    => 'Invalid Repository ID',
        },
    },

    fields => {
        filter => \&sc_filter_array_to_string,
    },

};

#-------------------------------------------------------------------------------
# METHODS
#-------------------------------------------------------------------------------

sub list {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        type   => {
            allow       => [ 'all', 'local', 'remote', 'offline' ],
            post_filter => sub {
                ucfirst(shift);
            }
        },
        raw => {},
    };

    my $params       = sc_check_params( $tmpl, \%args );
    my $raw          = delete( $params->{'raw'} );
    my $repositories = $self->client->get( '/repository', $params );

    return if ( !$repositories );

    if ($raw) {
        return wantarray ? @{$repositories} : $repositories;
    }

    return wantarray ? @{ sc_normalize_array($repositories) } : sc_normalize_array($repositories);

}

#-------------------------------------------------------------------------------

sub get {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        id     => $common_template->{'id'},
        raw    => {},
    };

    my $params        = sc_check_params( $tmpl, \%args );
    my $raw           = delete( $params->{'raw'} );
    my $repository_id = delete( $params->{'id'} );
    my $repository    = $self->client->get( "/repository/$repository_id", $params );

    return             if ( !$repository );
    return $repository if ($raw);
    return sc_normalize_hash($repository);

}

#-------------------------------------------------------------------------------

sub get_device_info {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields   => $common_template->{'fields'},
        id       => $common_template->{'id'},
        ip       => {},
        uuid     => {},
        dns_name => {
            remap => 'dnsName',
        }
    };

    my $params        = sc_check_params( $tmpl, \%args );
    my $repository_id = delete( $params->{'id'} );
    my $device_info   = $self->client->get( "/repository/$repository_id/deviceInfo", $params );

    return if ( !$device_info );
    return $device_info;

}

#-------------------------------------------------------------------------------

sub get_ip_info {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields   => $common_template->{'fields'},
        ip       => {},
        uuid     => {},
        dns_name => {
            remap => 'dnsName',
        }
    };

    my $params  = sc_check_params( $tmpl, \%args );
    my $ip_info = $self->client->get( "/ipInfo", $params );

    return if ( !$ip_info );
    return $ip_info;

}

#-------------------------------------------------------------------------------

1;

__END__