File Coverage

blib/lib/Net/SecurityCenter/API/PluginFamily.pm

Criterion	Covered	Total	%
statement	37	38	97.3
branch	5	10	50.0
condition			n/a
subroutine	8	8	100.0
pod	3	3	100.0
total	53	59	89.8

package Net::SecurityCenter::API::PluginFamily;

use warnings;
use strict;

use Carp;

use parent 'Net::SecurityCenter::Base';

use Net::SecurityCenter::Utils qw(:all);

our $VERSION = '0.300';

my $common_template = {

    id => {
        required => 1,
        allow    => qr/^\d+$/,
        messages => {
            required => 'Plugin Family ID is required',
            allow    => 'Invalid Plugin Family ID',
        },
    },

    op => {
        allow => [ 'eq', 'gt', 'gte', 'like', 'lt', 'lte' ]
    },

    type => {
        allow => [ 'active', 'all', 'compliance', 'custom', 'lce', 'notPassive', 'passive' ],
    },

    sort_field => {
        allow => [ 'modifiedTime', 'id', 'name', 'family', 'type' ],
        remap => 'sortDirection',
    },

    sort_direction => {
        allow  => [ 'ASC', 'DESC' ],
        remap  => 'sortDirection',
        filter => sub { uc $_[0] },
    },

    since => {
        allow => qr/^\d+$/,
    },

    start_offset => {
        allow => qr/^\d+$/,
        remap => 'startOffset',
    },

    end_offset => {
        allow => qr/^\d+$/,
        remap => 'endOffset',
    },

    filter_field => {
        allow => [
            'copyright',          'description',      'exploitAvailable', 'family',
            'id',                 'name',             'patchPubDate',     'patchModDate',
            'pluginPubDate',      'pluginModDate',    'sourceFile',       'type',
            'version',            'vulnPubDate',      'xrefs',            'xrefs:',
            'xrefs:ALAS',         'xrefs:APPLE-SA',   'xrefs:AUSCERT',    'xrefs:BID',
            'xrefs:CERT',         'xrefs:CERT-CC',    'xrefs:CERT-FI',    'xrefs:CERTA',
            'xrefs:CISCO-BUG-ID', 'xrefs:CISCO-SA',   'xrefs:CISCO-SR',   'xrefs:CLSA',
            'xrefs:CONECTIVA',    'xrefs:CVE',        'xrefs:CWE',        'xrefs:DSA',
            'xrefs:EDB-ID',       'xrefs:FEDORA',     'xrefs:FLSA',       'xrefs:FreeBSD',
            'xrefs:GLSA',         'xrefs:HP',         'xrefs:HPSB',       'xrefs:IAVA',
            'xrefs:IAVB',         'xrefs:IAVT',       'xrefs:ICS-ALERT',  'xrefs:ICSA',
            'xrefs:MDKSA',        'xrefs:MDVSA',      'xrefs:MGASA',      'xrefs:MSFT',
            'xrefs:MSVR',         'xrefs:NSFOCUS',    'xrefs:NessusID',   'xrefs:OSVDB',
            'xrefs:OWASP',        'xrefs:OpenPKG-SA', 'xrefs:RHSA',       'xrefs:SSA',
            'xrefs:Secunia',      'xrefs:SuSE',       'xrefs:TLSA',       'xrefs:TSLSA',
            'xrefs:USN',          'xrefs:VMSA',       'xrefs:zone-h'
        ],
        remap => 'filterField',
    },

    fields => {
        filter => \&sc_filter_array_to_string,
    },

};

#-------------------------------------------------------------------------------
# METHODS
#-------------------------------------------------------------------------------

sub list {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields         => $common_template->{'fields'},
        type           => $common_template->{'type'},
        sort_field     => $common_template->{'sort_field'},
        sort_direction => $common_template->{'sort_direction'},
        since          => $common_template->{'since'},
        filter_field   => $common_template->{'filter_field'},
        op             => $common_template->{'op'},
    };

    my $params   = sc_check_params( $tmpl, \%args );
    my $response = $self->client->get( '/pluginFamily', $params );

    return if ( !$response );

    return wantarray ? @{ sc_normalize_array($response) } : sc_normalize_array($response);

}

#-------------------------------------------------------------------------------

sub list_plugins {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields         => $common_template->{'fields'},
        id             => $common_template->{'id'},
        type           => $common_template->{'type'},
        sort_field     => $common_template->{'sort_field'},
        sort_direction => $common_template->{'sort_direction'},
        since          => $common_template->{'since'},
        start_offset   => $common_template->{'start_offset'},
        end_offset     => $common_template->{'end_offset'},
        filter_field   => $common_template->{'filter_field'},
        op             => $common_template->{'op'},
    };

    my $params           = sc_check_params( $tmpl, \%args );
    my $raw              = delete( $params->{'raw'} );
    my $plugin_family_id = delete( $params->{'id'} );
    my $plugins          = $self->client->get( "/pluginFamily/$plugin_family_id/plugins", $params );

    return          if ( !$plugins );
    return $plugins if ($raw);
    return sc_normalize_array($plugins);

}

#-------------------------------------------------------------------------------

sub get {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        id     => $common_template->{'id'},
    };

    my $params           = sc_check_params( $tmpl, \%args );
    my $plugin_family_id = delete( $params->{'id'} );

    my $response = $self->client->get( "/pluginFamily/$plugin_family_id", $params );

    return if ( !$response );
    return $response;

}

#-------------------------------------------------------------------------------

1;

__END__