File Coverage

blib/lib/Net/Presto.pm

Criterion	Covered	Total	%
statement	18	48	37.5
branch	0	10	0.0
condition			n/a
subroutine	6	11	54.5
pod	5	5	100.0
total	29	74	39.1

package Net::Presto;
use Moo;
use Furl;
use Carp qw(confess);
use Scalar::Util qw(blessed);
use JSON::XS;

our $VERSION = "0.01";

use Net::Presto::Statement;

has protocol => (
    is => 'ro',
    isa => sub { die "Unsupported protocol: $_[0]" unless $_[0] =~ /\Ahttps?\z/ },
    default => sub { 'http' },
);

has path => (
    is => 'ro',
    default => sub { '/v1/statement' },
);

has server => (
    is => 'ro',
    required => 1,
);

has catalog => (
    is => 'ro',
    required => 1,
);

has schema => (
    is => 'ro',
    required => 1,
);

has user => (
    is => 'ro',
    required => 1,
);

has time_zone => (
    is => 'ro',
);

has language => (
    is => 'ro',
);

has properties => (
    is => 'ro',
    isa => sub { die "properties is not a HashRef" unless ref $_[0] eq 'HASH' },
);

has furl => (
    is => 'ro',
    isa => sub { die "furl is not a Furl object" unless blessed $_[0] && $_[0]->isa('Furl') },
    default => sub {
        my $self = shift;
        Furl->new(
            agent   => $self->source,
            timeout => 180,
        );
    },
);

has source => (
    is => 'ro',
    default => sub { join('/', __PACKAGE__, $VERSION) },
);

sub execute {
    my ($self, $query) = @_;
    confess 'No query specified' unless defined $query;
    my $url = sprintf '%s://%s%s', $self->protocol, $self->server, $self->path;
    my $headers = [
        'X-Presto-User'    => $self->user,
        'X-Presto-Source'  => $self->source,
        'X-Presto-Catalog' => $self->catalog,
        'X-Presto-Schema'  => $self->schema,
        $self->time_zone  ? ('X-Presto-Time-Zone' => $self->time_zone) : (),
        $self->language   ? ('X-Presto-Language'  => $self->language) : (),
        $self->properties ? (
            map {
                ('X-Presto-Session' => join('=', $_, $self->properties->{$_})) # need to validate?
            } keys %{$self->properties}
        ) : (),
    ];
    my $response = $self->furl->post($url, $headers, $query);
    confess $response->status_line unless $response->is_success;
    my $res = decode_json $response->content;
    Net::Presto::Statement->create(
        furl    => $self->furl,
        headers => $headers,
        res     => $res,
    );
}

sub do {
    my ($self, $query) = @_;
    my $st = $self->execute($query);
    $st->wait_for_completion;
    1;
}

sub select_one {
    my ($self, $query) = @_;
    my $st = $self->execute($query);
    my $rows = $st->fetch;
    $st->wait_for_completion;
    $rows->[0]->[0];
}

sub select_row {
    my ($self, $query) = @_;
    my $st = $self->execute($query);
    my $rows = $st->fetch_hashref;
    $st->wait_for_completion;
    $rows->[0];
}

sub select_all {
    my ($self, $query) = @_;
    my $st = $self->execute($query);
    my @rows;
    while (my $rows = $st->fetch_hashref) {
        push @rows, @$rows;
    }
    \@rows;
}

1;
__END__