File Coverage

blib/lib/Net/Plywood/Simple.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package Net::Plywood::Simple;
use 5.006;
use strict;
use warnings;

use HTTP::Tiny;
use Try::Tiny;
use JSON;

our $VERSION = 0.05;

############
## Public ##
############

sub new
{
	my $class  = shift;
	my $params = ref($_[0]) ? $_[0] : {@_};
	if (!$params->{scheme} || !$params->{host} || !$params->{port}) {
		die "arguments 'scheme', 'host' and 'port' are required";
	}
	$params->{_url}  = "$params->{scheme}://$params->{host}:$params->{port}";
	$params->{_json} = JSON->new->utf8;
	return bless($params, $class);
}

sub disjoin
{
	my ($self, $tree_key, $disjoin) = @_;
	if (!$disjoin->{key} || !$disjoin->{value}) {
		die "arguments 'key', 'value' are required to disjoin a tree";
	}
	return $self->mutate(
		$tree_key,
		{
			filter => {
				field => $disjoin->{key},
				op    => '!=',
				value => $disjoin->{value},
			}
		},
	);
}

sub get
{
	my ($self, $tree_key, @path) = @_;
	my $path = join('/', @path);
	my $response;
	try {
		$response = HTTP::Tiny->new->get($self->_url . "/tree/$tree_key/$path");
	} catch {
		die "could not get tree, error was: $_";
	};
	if (!$response->{success}) {
		die "$response->{reason} ($response->{status}): $response->{content}";
	}
	return $response;
}

sub mutate
{
	my ($self, $tree_key, $data) = @_;
	my $response;
	my $json = $self->_to_json($data);
	try {
		$response = HTTP::Tiny->new->post(
			$self->_url . "/mutate/$tree_key",
			{content => $json},
		);
	} catch {
		die "could not mutate tree, error was: $_";
	};
	if (!$response->{success}) {
		die "$response->{reason} ($response->{status}): $response->{content}";
	}
	return $response;
}

sub put
{
	my ($self, $tree_key, $data) = @_;
	if ($tree_key =~ m/\//) {
		die 'can not have forward slash ( / ) characters in key names';
	}
	my $response;
	my $json = $self->_to_json($data);
	try {
		$response = HTTP::Tiny->new->put(
			$self->_url . "/tree/$tree_key",
			{content => $json},
		);
	} catch {
		die "could not store tree, error was: $_";
	};
	if (!$response->{success}) {
		die "$response->{reason} ($response->{status}): $response->{content}";
	}
	return $response;
}

#############
## Private ##
#############

sub _to_json
{
	my ($self, $data) = @_;
	my $json;
	try {
		$json = $self->_json->encode($data);
	} catch {
		die "could not encode data as JSON, error was: $_";
	};
	return $json;
}

sub _from_json
{
	my ($self, $json) = @_;
	my $data;
	try {
		$data = $self->_json->decode($json);
	} catch {
		die "could not decode data which we thought was JSON, error was: $_";
	};
	return $data;
}

sub _json {return shift->{_json}}
sub _url  {return shift->{_url}}

1;

__END__