File Coverage

blib/lib/Net/POP3S.pm

Criterion	Covered	Total	%
statement	15	81	18.5
branch	0	38	0.0
condition	0	27	0.0
subroutine	5	7	71.4
pod			n/a
total	20	153	13.0

# ====
#  SSL/STARTTLS extention for Graham Barr's Net::POP3.
#    plus, enable arbitrary POP auth mechanism selection.
#      IO::Socket::SSL (also Net::SSLeay openssl),
#      Authen::SASL, MIME::Base64 should be installed.
#
package Net::POP3S;

use vars qw ( $VERSION @ISA );

$VERSION = '0.08';

use strict;
use base qw ( Net::POP3 );
use Net::Cmd;  # import CMD_OK, CMD_MORE, ...
use Net::Config;

eval {
    require IO::Socket::IP
	and unshift @ISA, 'IO::Socket::IP';
} or eval {
    require IO::Socket::INET6
	and unshift @ISA, 'IO::Socket::INET6';
} or do {
    require IO::Socket::INET
	and unshift @ISA, 'IO::Socket::INET';
};

# Override to support SSL/TLS.
sub new {
  my $self = shift;
  my $type = ref($self) || $self;
  my ($host, %arg);
  if (@_ % 2) {
      $host = shift;
      %arg  = @_;
  }
  else {
      %arg  = @_;
      $host = delete $arg{Host};
  }
  my $ssl = delete $arg{doSSL};
  if ($ssl =~ /ssl/i) {
      $arg{SSL} = 1;
  }
  if (defined($arg{SSL}) && $arg{SSL} > 0) {
      $ssl = 'ssl';
      $arg{Port} ||= 995;
  }

  my $hosts = defined $host ? $host : $NetConfig{pop3_hosts};
  my $obj;

  # eliminate IO::Socket::SSL from @ISA for multiple call of new.
  @ISA = grep { !/IO::Socket::SSL/ } @ISA;

  my %_args = map { +"$_" => $arg{$_} } grep {! /^SSL/} keys %arg;

  my $h;
  $_args{PeerPort} = $_args{Port} || 'pop3(110)';
  $_args{Proto} = 'tcp';
  $_args{Timeout} = defined $_args{Timeout} ? $_args{Timeout} : 120;
  if (exists $_args{ResvPort}) {
      $_args{LocalPort} = delete $_args{ResvPort};
  }

  foreach $h (@{ref($hosts) ? $hosts : [$hosts]}) {
      $_args{PeerAddr} = ($host = $h);

      $obj = $type->SUPER::new(
	  %_args
      )
      and last;
  }

  return undef
    unless defined $obj;

  ${*$obj}{'net_pop3_host'} = $host;

  $obj->autoflush(1);
  $obj->debug(exists $arg{Debug} ? $arg{Debug} : undef);

# common in SSL
  my %ssl_args;
  if ($ssl || defined($arg{SSL}) ) {
    eval {
      require IO::Socket::SSL;
    } or do {
      $obj->set_status(500, ["Need working IO::Socket::SSL"]);
      $obj->close;
      return undef;
    };
    %ssl_args = map { +"$_" => $arg{$_} } grep {/^SSL/} keys %arg;
    $IO::Socket::SSL::DEBUG = (exists $arg{Debug} ? $arg{Debug} : undef);
  }

# OverSSL
  if (defined($ssl) && $ssl =~ /ssl/i) {
    $obj->ssl_start(\%ssl_args)
      or do {
	 $obj->set_status(500, ["Cannot start SSL"]);
	 $obj->close;
	 return undef;
      };
  }

  unless ($obj->response() == CMD_OK) {
    $obj->close();
    return undef;
  }

  ${*$obj}{'net_pop3_banner'} = $obj->message;
  ${*$obj}{'net_pop3_arg'} = \%arg;

# STARTTLS
  if (defined($ssl) && $ssl =~ /starttls|stls/i ) {
      unless ($obj->starttls()) {
	  return undef;
      }
  }

  $obj;
}

sub ssl_start {
    my ($self, $args) = @_;
    my $type = ref($self);

    (unshift @ISA, 'IO::Socket::SSL'
     and IO::Socket::SSL->start_SSL($self, %$args)
     and $self->isa('IO::Socket::SSL')
     and bless $self, $type     # re-bless 'cause IO::Socket::SSL blesses himself.
    ) or return undef;
}

sub starttls {
    my $self = shift;
    my %arg = %{ ${*$self}{'net_pop3_arg'} };
    my %ssl_args = map { +"$_" => $arg{$_} } grep {/^SSL/} keys %arg;
    my $capa;
    ($capa = $obj->capa
     and exists $capa->{STLS}
     and $self->_STLS()
     and $self->ssl_start(\%ssl_args, @_)
    ) or do {
	$self->set_status(500, ["Cannot start SSL session"]);
	$self->close();
	return undef;
    };
}

sub capa {
    my $this = shift;

    if (exists ${*$this}{'net_pop3e_capabilities'}) {
	return ${*$this}{'net_pop3e_capabilities'};
    }
    $this->SUPER::capa();
}

# Override to specify a certain auth mechanism.
sub auth {
  my ($self, $username, $password, $mech) = @_;

  if ($mech) {
      $self->debug_print(1, "my favorite: ". $mech . "\n") if $self->debug;

      my @cl_mech = split /\s+/, $mech;
      my @matched = ();
      my $sv = $self->capa->{SASL} || 'CRAM-MD5';

      foreach my $i (@cl_mech) {
	  if (index($sv, $i) >= 0 && grep(/$i/i, @matched) == () ) {
	      push @matched, uc($i);
	  }
      }
      if (@matched) {
      ## override AUTH mech as specified.
      ## if multiple mechs are specified, priority is still up to Authen::SASL module.
	  ${*$self}{'net_pop3e_capabilities'}->{'SASL'} = join " ", @matched;
      }
  }
  $self->SUPER::auth($username, $password);
}

sub _STLS { shift->command("STLS")->response() == CMD_OK }

# Fix #121006 no timeout issue.
sub getline {
  my $self = shift;
  $self->Net::Cmd::getline(@_);
}

1;

__END__