File Coverage

lib/Net/LDAP/SimpleServer.pm

Criterion	Covered	Total	%
statement	72	82	87.8
branch	9	14	64.2
condition	2	5	40.0
subroutine	17	18	94.4
pod	4	4	100.0
total	104	123	84.5

package Net::LDAP::SimpleServer;

use strict;
use warnings;

# ABSTRACT: Minimal-configuration, read-only LDAP server

our $VERSION = '0.0.21';    # VERSION

use 5.008;
use Carp;

our $personality = undef;

sub import {
    my $pkg = shift;
    $personality = shift || 'Fork';

    eval "use base qw{Net::Server::$personality}";    ## no critic
    croak $@ if $@;

    push @Net::LDAP::SimpleServer::ISA, qw(Net::Server);
    return;
}

use File::Basename;
use File::HomeDir;
use File::Spec;
use File::Path 2.08 qw{make_path};
use Scalar::Util qw{reftype};
use Net::LDAP::SimpleServer::LDIFStore;
use Net::LDAP::SimpleServer::ProtocolHandler;
use Net::LDAP::SimpleServer::Constant;

my $BASEDIR             = File::Spec->catfile( home(),   '.ldapsimple' );
my $DEFAULT_CONFIG_FILE = File::Spec->catfile( $BASEDIR, 'server.conf' );
my $DEFAULT_DATA_FILE   = File::Spec->catfile( $BASEDIR, 'server.ldif' );
my $DEFAULT_LOG_FILE    = File::Spec->catfile( $BASEDIR, 'server.log' );

my @LDAP_PRIVATE_OPTIONS = qw/store input output/;
my @LDAP_PUBLIC_OPTIONS =
  qw/data_file root_dn root_pw allow_anon user_passwords user_id_attr user_pw_attr user_filter/;

make_path($BASEDIR);

sub options {
    my ( $self, $template ) = @_;
    my $prop = $self->{server};

    ### setup options in the parent classes
    $self->SUPER::options($template);

    ### add a single value option
    for (@LDAP_PUBLIC_OPTIONS) {
        $prop->{$_} = undef unless exists $prop->{$_};
        $template->{$_} = \$prop->{$_};
    }

    #use Data::Dumper;
    #print STDERR Data::Dumper->Dump( [$self->{server}], ['server'] );
    return;
}

sub default_values {
    my $self = @_;

    my $v = {};
    $v->{port}      = 389;
    $v->{log_file}  = $DEFAULT_LOG_FILE;
    $v->{conf_file} = $DEFAULT_CONFIG_FILE if -r $DEFAULT_CONFIG_FILE;
    $v->{syslog_ident} =
      'Net::LDAP::SimpleServer [' . $Net::LDAP::SimpleServer::VERSION . ']';

    $v->{allow_anon}     = 1;
    $v->{root_dn}        = 'cn=root';
    $v->{data_file}      = $DEFAULT_DATA_FILE if -r $DEFAULT_DATA_FILE;
    $v->{user_passwords} = USER_PW_NONE;
    $v->{user_filter}    = '(objectClass=person)';
    $v->{user_id_attr}   = 'uid';
    $v->{user_pw_attr}   = 'userPassword';

    #use Data::Dumper; print STDERR Dumper($v);
    return $v;
}

sub post_configure_hook {
    my $self = shift;
    my $prop = $self->{server};

    # create server directory in home dir
    make_path($BASEDIR);

    #use Data::Dumper; print STDERR '# ' . Dumper( $prop );
    croak q{Configuration has no "data_file" file!}
      unless $prop->{data_file};
    croak qq{Cannot read data_file file (} . $prop->{data_file} . q{)}
      unless -r $prop->{data_file};

    # data_file is not a "public" option in the server, it is created here
    $prop->{store} =
         Net::LDAP::SimpleServer::LDIFStore->new( $prop->{data_file} )
      || croak q{Cannot create data store!};

    return;
}

sub process_request {
    my $self = shift;
    my $prop = $self->{server};

    my $params = { map { ( $_ => $prop->{$_} ) } @LDAP_PUBLIC_OPTIONS };
    for (@LDAP_PRIVATE_OPTIONS) {
        $params->{$_} = $prop->{$_} if $prop->{$_};
    }
    $params->{sock} = $self->{server}->{client};
    my $handler = Net::LDAP::SimpleServer::ProtocolHandler->new($params);

    until ( $handler->handle ) {

        # intentionally empty loop
    }
    return;
}

1;    # Magic true value required at end of module

__END__