File Coverage

blib/lib/Net/LDAP/FilterBuilder.pm

Criterion	Covered	Total	%
statement	51	52	98.0
branch	11	12	91.6
condition	2	3	66.6
subroutine	10	10	100.0
pod	4	6	66.6
total	78	83	93.9

package Net::LDAP::FilterBuilder;
BEGIN {
  $Net::LDAP::FilterBuilder::VERSION = '1.200002';
}

use strict;
use warnings FATAL => 'all';

use overload '""' => \&as_str;

sub escape {
    my $class = shift;
    my $value = shift;
    for ( $value ) {
        s{\\}{\\}g;
        s{\*}{\\*}g;
        s{\(}{\\(}g;
        s{\)}{\\)}g;
        s{\0}{\\0}g;
    }
    return $value;
}

sub new {
    my $proto = shift;
    my $class = ref( $proto ) || $proto;

    my $filter;

    if ( @_ == 0 ) {
        $filter = '(objectclass=*)';
    }
    elsif ( @_ == 1 ) {
        $filter = shift;
    }
    else {
        my $op = @_ % 2 ? shift : '=';
        my @parts;
        while ( my ( $attr, $val ) = splice( @_, 0, 2 ) ) {
            if ( ref( $val ) eq 'ARRAY' ) {
                push @parts, sprintf( '(|%s)', join( q{}, map $class->new( $op, $attr, $_ ), @{ $val } ) );
            }
            elsif ( ref( $val ) eq 'SCALAR' ) {
                push @parts, sprintf( '(%s%s%s)', $attr, $op, ${ $val } );
            }
            else {
                push @parts, sprintf( '(%s%s%s)', $attr, $op, $class->escape( $val ) );
            }
        }
        if ( @parts > 1 ) {
            $filter = sprintf( '(&%s)', join( q{}, @parts ) );
        }
        else {
            $filter = shift @parts;
        }
    }

    bless( \$filter, $class );
}

sub or {
    my $self = shift;

    ${ $self } = sprintf( '(|%s%s)', $self, $self->new( @_ ) );

    return $self;
}

sub and {
    my $self = shift;

    ${ $self } = sprintf( '(&%s%s)', $self, $self->new( @_ ) );

    return $self;
}

sub not {
    my $self = shift;

    ${ $self } = sprintf( '(!%s)', $self );

    return $self;
}

sub as_str {
    ${ $_[0] };
}

1;

# ABSTRACT: Build LDAP filter statements


__END__