File Coverage

blib/lib/Net/IPMessenger/RecvEventHandler.pm

Criterion	Covered	Total	%
statement	28	57	49.1
branch	5	18	27.7
condition	1	3	33.3
subroutine	7	12	58.3
pod	8	8	100.0
total	49	98	50.0

package Net::IPMessenger::RecvEventHandler;

use warnings;
use strict;
use IO::Socket;
use base qw( Net::IPMessenger::EventHandler );

sub BR_ENTRY {
    my( $self, $ipmsg, $user ) = @_;
    my $command = $ipmsg->messagecommand('ANSENTRY');
    $command->set_encrypt if $ipmsg->encrypt;
    $ipmsg->send(
        {
            command => $command,
            option  => $ipmsg->my_info,
        }
    );
}

sub ANSLIST {
    my( $self, $ipmsg, $user ) = @_;
    my $key      = $user->key;
    my $peeraddr = inet_ntoa( $ipmsg->socket->peeraddr );

    $ipmsg->parse_anslist( $user, $peeraddr );
    delete $ipmsg->user->{$key};
}

sub SENDMSG {
    my( $self, $ipmsg, $user ) = @_;
    my $command = $ipmsg->messagecommand( $user->command );
    if ( $command->get_sendcheck ) {
        $ipmsg->send(
            {
                command => $ipmsg->messagecommand('RECVMSG'),
                option  => $user->packet_num,
            }
        );
    }

    # decrypt message if the message is encrypted
    # and encryption support is available
    if ( $command->get_encrypt and $ipmsg->encrypt ) {
        my $encrypt = $ipmsg->encrypt;
        my $decrypted = $encrypt->decrypt_message( $user->get_message );
        $user->option($decrypted);
        if ( $command->get_fileattach ) {
            $user->attach( $encrypt->attach );
        }
    }
    elsif ( $command->get_fileattach ) {
        my( $option, $attach ) = split /\0/, $user->get_message;
        $user->option($option);
        $user->attach($attach);
    }
    push @{ $ipmsg->message }, $user;
}

sub RECVMSG {
    my( $self, $ipmsg, $user ) = @_;
    my $option = $user->option;
    $option =~ s/\0//g;
    if ( exists $ipmsg->sending_packet->{$option} ) {
        delete $ipmsg->sending_packet->{$option};
    }
}

sub READMSG {
    my( $self, $ipmsg, $user ) = @_;
    my $command = $ipmsg->messagecommand( $user->command );
    if ( $command->get_readcheck ) {
        $ipmsg->send(
            {
                command => $ipmsg->messagecommand('ANSREADMSG'),
                option  => $user->packet_num,
            }
        );
    }
}

sub GETINFO {
    my( $self, $ipmsg, $user ) = @_;
    $ipmsg->send(
        {
            command => $ipmsg->messagecommand('SENDINFO'),
            option  => sprintf( "Net::IPMessenger-%s", $ipmsg->VERSION ),
        }
    );
}

sub GETPUBKEY {
    my( $self, $ipmsg, $user ) = @_;
    return unless $ipmsg->encrypt;
    $ipmsg->send(
        {
            command => $ipmsg->messagecommand('ANSPUBKEY'),
            option  => $ipmsg->encrypt->public_key_string,
        }
    );
}

sub ANSPUBKEY {
    my( $self, $ipmsg, $user ) = @_;
    return unless $ipmsg->encrypt;
    my $key     = $user->key;
    my $message = $user->get_message;
    my( $option, $public_key ) = split /:/,  $message;
    my( $exponent, $modulus )  = split /\-/, $public_key;
    $ipmsg->user->{$key}->pubkey(
        {
            option   => $option,
            exponent => $exponent,
            modulus  => $modulus,
        }
    );
}

1;
__END__