File Coverage

blib/lib/Net/IPAddress/Filter/IPFilterDat.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	9	10	90.0
condition	5	10	50.0
subroutine	9	9	100.0
pod	2	2	100.0
total	64	70	91.4

package Net::IPAddress::Filter::IPFilterDat;

use strict;
use warnings;

# ABSTRACT: A fast IP address filter from ipfilter.dat
our $VERSION = '20121119.02'; # VERSION

use Scalar::Util ();

use Net::IPAddress::Filter 20121117;
use base qw( Net::IPAddress::Filter );


use constant {

    # 000.000.000.000 - 000.255.255.255 , 000 , invalid ip
    RULE_REGEX => qr{
        \A \s*
        ([0-9]{1,3} \. [0-9]{1,3} \. [0-9]{1,3} \. [0-9]{1,3}) # Start IP address
        \s* - \s*
        ([0-9]{1,3} \. [0-9]{1,3} \. [0-9]{1,3} \. [0-9]{1,3}) # End IP address
        \s* , \s*
        (\d+)                                                  # Score
        \s* , \s*
        (.*?)                                                  # Label
        \s* \z
    }xms,
};


sub load_file {
    my $self = shift;
    my $file = shift || return;

    my $FH;

    # A filehandle can be a GLOB ref, or a blessed ref to one of the IO::
    # packages.  reftype() handles boths cases.
    if ( ref($file)
        && ( Scalar::Util::reftype($file) eq 'GLOB' || Scalar::Util::reftype( \$file ) eq 'GLOB' ) )
    {
        $FH = $file;
    }
    else {
        open $FH, '<', $file
            or die __PACKAGE__ . "::load_file() unable to open $file for reading: $!";
    }

    my $rules_added = 0;
    while ( my $line = <$FH> ) {
        $rules_added++ if $self->add_rule($line);
    }

    close $FH;

    return $rules_added;
}


sub add_rule {
    my $self = shift;
    my $rule = shift || return 0;

    if ( my $data = _parse_rule($rule) ) {
        $self->add_range_with_value( $data->{label}, $data->{start_ip}, $data->{end_ip} );
        return 1;
    }

    return 0;
}


sub _parse_rule {
    my $rule = shift;

    # 000.000.000.000 - 000.255.255.255 , 000 , invalid ip
    if ( $rule =~ RULE_REGEX ) {
        return {
            start_ip => $1,
            end_ip   => $2,
            score    => $3,
            label    => $4,
        };
    }
    return;
}

1;

__END__